ARM9的存儲(chǔ)控制器

實(shí)驗(yàn)的目的：
把程序本身從Steppingstone復(fù)制到SDRAM處，然后跳轉(zhuǎn)到SDRAM中執(zhí)行

實(shí)驗(yàn)的源程序：
@*************************************************************************
@ File：head.S
@ 功能：設(shè)置SDRAM，將程序復(fù)制到SDRAM，然后跳到SDRAM繼續(xù)執(zhí)行
@*************************************************************************

.equ MEM_CTL_BASE, 0x48000000
.equ SDRAM_BASE, 0x30000000

.text
.global _start
_start:
bl disable_watch_dog @ 關(guān)閉WATCHDOG，否則CPU會(huì)不斷重啟
bl memsetup @ 設(shè)置存儲(chǔ)控制器
bl copy_steppingstone_to_sdram @ 復(fù)制代碼到SDRAM中
ldr pc, =on_sdram @ 跳到SDRAM中繼續(xù)執(zhí)行
on_sdram:
ldr sp, =0x34000000 @ 設(shè)置堆棧
bl main
halt_loop:
b halt_loop

disable_watch_dog:
@ 往WATCHDOG寄存器寫0即可
mov r1, #0x53000000
mov r2, #0x0
str r2, [r1]
mov pc, lr @ 返回

copy_steppingstone_to_sdram:
@ 將Steppingstone的4K數(shù)據(jù)全部復(fù)制到SDRAM中去
@ Steppingstone起始地址為0x00000000，SDRAM中起始地址為0x30000000

mov r1, #0
ldr r2, =SDRAM_BASE
mov r3, #4*1024
1:
ldr r4, [r1],#4 @ 從Steppingstone讀取4字節(jié)的數(shù)據(jù)，并讓源地址加4
str r4, [r2],#4 @ 將此4字節(jié)的數(shù)據(jù)復(fù)制到SDRAM中，并讓目地地址加4
cmp r1, r3 @ 判斷是否完成：源地址等于Steppingstone的未地址？
bne 1b @ 若沒有復(fù)制完，繼續(xù)
mov pc, lr @ 返回

memsetup:
@ 設(shè)置存儲(chǔ)控制器以便使用SDRAM等外設(shè)

mov r1, #MEM_CTL_BASE @ 存儲(chǔ)控制器的13個(gè)寄存器的開始地址
adrl r2, mem_cfg_val @ 這13個(gè)值的起始存儲(chǔ)地址
add r3, r1, #52 @ 13*4 = 54
1: @這是數(shù)值1，專業(yè)術(shù)語叫局部標(biāo)號(hào)，主要用于bne 1b這條語句
ldr r4, [r2], #4 @ 讀取設(shè)置值，并讓r2加4
str r4, [r1], #4 @ 將此值寫入寄存器，并讓r1加4
cmp r1, r3 @ 判斷是否設(shè)置完所有13個(gè)寄存器
bne 1b @ 若沒有寫成，繼續(xù)
mov pc, lr @ 返回

.align 4
mem_cfg_val:
@ 存儲(chǔ)控制器13個(gè)寄存器的設(shè)置值
.long 0x22011110 @ BWSCON @其實(shí)BWSCON這個(gè)寄存器的設(shè)置，主要是綜合了存儲(chǔ)控制器的其余BANK和外圍器件的連接
.long 0x00000700 @ BANKCON0 @一下這些寄存器的設(shè)置，都可以參考韋東山老師的書籍
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7
.long 0x008C07A3 @ REFRESH
.long 0x000000B1 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7

/**************************************************************************
led.c
**************************************************************************/

#define GPFCON (*(volatile unsigned long *)0x56000050)
#define GPFDAT (*(volatile unsigned long *)0x56000054)

#define GPF4_out (1<<(4*2))
#define GPF5_out (1<<(5*2))
#define GPF6_out (1<<(6*2))

void wait(volatile unsigned long dly)
{
for(; dly > 0; dly--);
}


int main(void)
{
unsigned long i = 0;

GPFCON = GPF4_out|GPF5_out|GPF6_out; // 將LED1,2,4對應(yīng)的GPF4/5/6三個(gè)引腳設(shè)為輸出

while(1)
{
wait(30000);
GPFDAT = (~(i<<4)); // 根據(jù)i的值，點(diǎn)亮LED1,2,4
if(++i == 8)
i = 0;
}

return 0;

}

/**************************************************************************
Makefile
**************************************************************************/

sdram.bin : head.S leds.c
arm-linux-gcc -c -o head.o head.S
arm-linux-gcc -c -o leds.o leds.c
arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
arm-linux-objcopy -O binary -S sdram_elf sdram.bin
arm-linux-objdump -D -m arm sdram_elf > sdram.dis
clean:
rm -f sdram.dis sdram.bin sdram_elf *.o

實(shí)驗(yàn)的問題總結(jié)：
I.在這期間，存儲(chǔ)控制器起了一個(gè)什么作用？
在S3C2440/S3C2410中，對外引出的27根地址線ADDR0-ADDR26的訪問范圍只有128M，
CPU對外還引出了8根片選信號(hào)nGCS0-nGCS7，對應(yīng)于BANK0-BANK7，當(dāng)某一個(gè)片選信號(hào)拉低時(shí)，
對應(yīng)的存儲(chǔ)控制器的BANK就被選中，而每個(gè)BANK都是和外部設(shè)備相連的，當(dāng)CPU發(fā)出某一地址信號(hào)時(shí)，
它會(huì)通過讀取存儲(chǔ)控制器的中的寄存器的配置信息，從而就知道了如何去訪問外部的設(shè)備。我想這
大概就是存儲(chǔ)控制器的作用。

II.存儲(chǔ)控制器的BANK和SDRAM的Bank有什么區(qū)別？
存儲(chǔ)控制器的BANK
在TQ2440中，存儲(chǔ)控制器的BANK有8個(gè)，可以分別接8個(gè)不同的器件，通過片選信號(hào)使各個(gè)器件可以獨(dú)立開來訪問；
SDRAM的Bank
SDRAM的內(nèi)部是一個(gè)存儲(chǔ)陣列。陣列就如同那么表格一樣，將數(shù)據(jù)“填”進(jìn)去，你可以把它想象成一張表格。
和表格的檢索原理一樣，先指定一個(gè)行（Row），再指定一個(gè)列（Column），
我們就可以準(zhǔn)確地找到所需要的單元格，這就是內(nèi)存芯片尋址的基本原理。
對于內(nèi)存，這個(gè)單元格可稱為存儲(chǔ)單元,那么這個(gè)表格（存儲(chǔ)陣列）叫什么呢？
它就是邏輯 Bank（Logical Bank，下文簡稱L-Bank），所以說，準(zhǔn)備的說SDRAM的Bank叫L-Bank

III.怎么確定SDRAM是接存儲(chǔ)控制器的哪個(gè)BANK？還有就是每個(gè)BANK的對應(yīng)的地址又是如何確定的？
關(guān)于SDRAM是接在存儲(chǔ)控制器的哪個(gè)BANK上的，可以通過開發(fā)板的原理圖的片選信號(hào)得知，因?yàn)槠x信號(hào)和BANK是一一對應(yīng)的；
當(dāng)我們知道了SDRAM的是接在哪個(gè)BANK之后，接下來，我們?nèi)绾沃肋@個(gè)SDRAM的地址呢？這主要是在S3C2440中的用戶手冊中
有介紹，對于每一個(gè)存儲(chǔ)控制器的BANK，其地址都已經(jīng)規(guī)定好了。

IV.既然在Makefile中，指定的鏈接地址是：0x3000 0000 ,那按理說這些代碼段剛開始都是在SDRAM中執(zhí)行的啊，而剛開始SDRAM
又沒有初始化，這不矛盾么？
主要的原因是，在代碼段中，bl disable_watch_dog，bl memsetup，bl copy_steppingstone_to_sdram，因?yàn)槎际窍鄬μD(zhuǎn)，所以說這些都是位置無關(guān)的幾條指令，也就是說，這些代碼即使不在鏈接時(shí)所指定的運(yùn)行時(shí)地址空間，也可以正確執(zhí)行，它是一段加載到任意地址空間都能正常執(zhí)行的特殊代碼。當(dāng)程序運(yùn)行到ldr pc, =on_sdram 條指令的時(shí)候，由于是取on_sdram的絕對地址，而其地址標(biāo)號(hào)是在SDRAM中的，所以說，執(zhí)行完這條語句之后，程序就在SDRAM中運(yùn)行了。關(guān)于這一點(diǎn)，可以百度一下位置無關(guān)代碼的知識(shí)。


注：可參考的書籍《嵌入式Linux應(yīng)用開發(fā)完全手冊》