用MAXQ3210構(gòu)建1-Wire溫度記錄儀

概述

    環(huán)境監(jiān)測通常需要小巧靈活的微控制器。如果在這類應(yīng)用中使用個(gè)人電腦，對其計(jì)算能力和存儲(chǔ)容量而言都是一種浪費(fèi)，可采用一個(gè)專用微控制器與溫、濕度傳感器或其它環(huán)境監(jiān)測傳感器通信，讀取并存儲(chǔ)監(jiān)測數(shù)據(jù)。為實(shí)現(xiàn)更高的靈活性，這些微控制器可連成網(wǎng)絡(luò)，各自將監(jiān)測數(shù)據(jù)上傳到功能更強(qiáng)大的系統(tǒng)中，對整體環(huán)境參數(shù)進(jìn)行分析記錄。

    本篇應(yīng)用筆記介紹如何使用低功耗微控制器MAXQ3210實(shí)現(xiàn)環(huán)境監(jiān)測應(yīng)用。增加一個(gè)通過一根1-Wire總線實(shí)現(xiàn)供電和通信的數(shù)字溫度傳感器DS1822，我們可用最少的元器件構(gòu)建一個(gè)電池供電的非易失溫度記錄系統(tǒng)。

    可以下載相關(guān)演示代碼。代碼采用MAXQ匯編語言編寫，在MAX-IDE開發(fā)環(huán)境自帶的標(biāo)準(zhǔn)宏匯編預(yù)處理器和匯編器中編譯。該代碼是為MAXQ3210評估板編寫，因此還需要以下器件(圖1)。

    溫度傳感器：DS1822經(jīng)濟(jì)型1-Wire數(shù)字溫度傳感器(TO-92封裝)
RS-232電平轉(zhuǎn)換器：MAX233ACWP

圖1. MAXQ3210 1-Wire溫度記錄儀演示電路所需的元器件

設(shè)計(jì)目標(biāo)

演示代碼要完成以下任務(wù)(圖2)：
通過1-Wire網(wǎng)絡(luò)(位模擬方式)與溫度傳感器DS1822通信。
每分鐘喚醒一次測量溫度。
將溫度數(shù)據(jù)存儲(chǔ)在MAXQ3210內(nèi)部的非易失EEPROM中。
上電后以9600bps的速率通過位模擬串口發(fā)送溫度記錄數(shù)據(jù)。
在發(fā)送前將溫度數(shù)據(jù)轉(zhuǎn)換成容易識(shí)別的ASCII格式(十進(jìn)制華氏度)。
根據(jù)主機(jī)要求清空存儲(chǔ)器(擦除在EEPROM中存儲(chǔ)的溫度數(shù)據(jù))。

圖2. 溫度記錄應(yīng)用的程序流程圖

為何使用MAXQ3210

    幾乎所有的低功耗MAXQ微控制器都可以實(shí)現(xiàn)這一應(yīng)用，但MAXQ3210更適合用于溫度記錄。

    集成穩(wěn)壓器。MAXQ3210內(nèi)部集成5V穩(wěn)壓器，可以直接由標(biāo)準(zhǔn)9V電池供電。MAXQ3210的5V穩(wěn)壓輸出還可為其它設(shè)備供電(最大電流50mA)。這一特性非常重要，這意味著如果其它器件也可采用5V供電，則不再需要另加單獨(dú)的電源芯片。

    低功耗。MAXQ3210僅需消耗很小的電流，即使以3.58MHz全速運(yùn)行，典型值也僅為6mA。當(dāng)降低頻率或處理器停止工作進(jìn)入休眠狀態(tài)時(shí)，電池電流還可更低。MAXQ3210內(nèi)部集成的8kHz環(huán)形振蕩器驅(qū)動(dòng)一個(gè)長周期的喚醒時(shí)鐘，可在長達(dá)2分鐘的可編程間隔后將處理器從休眠狀態(tài)喚醒。

    內(nèi)部數(shù)據(jù)EEPROM。在掉電時(shí)需要保存溫度記錄數(shù)據(jù)，這些數(shù)據(jù)可能要采集幾小時(shí)，幾天，甚至是幾周時(shí)間。MAXQ3210數(shù)據(jù)存儲(chǔ)空間有64個(gè)字的 EEPROM，可非常容易的實(shí)現(xiàn)這一要求。EEPROM中的每個(gè)16位字都可調(diào)用Utility ROM中的一個(gè)函數(shù)單獨(dú)修改；EEPROM技術(shù)意味著在寫數(shù)據(jù)之前從來都不需要擦除操作。如果需要更多EEPROM空間，可將數(shù)據(jù)寫入任何未用的程序 EEPROM空間，該寫入過程調(diào)用Utility ROM中的另一個(gè)函數(shù)以類似方式逐字修改，無需重載整個(gè)應(yīng)用程序。

    5V端口引腳。與所有MAXQ微控制器一樣，MAXQ3210的端口引腳可靈活的設(shè)為輸入、輸出、弱上拉和三態(tài)。MAXQ3210還可提供多種接口選擇。由于微控制器的端口為5V電平，可以直連5V器件或通過上拉電阻連接低功耗器件(工作在三態(tài)/開漏模式)。由于這一應(yīng)用所需端口很少，使用大的微控制器會(huì)浪費(fèi)許多功能。

    壓電揚(yáng)聲器驅(qū)動(dòng)器。盡管壓電揚(yáng)聲器功能在這一應(yīng)用中沒有使用，但在許多類型的環(huán)境監(jiān)測應(yīng)用中都需要產(chǎn)生可聽見的告警聲。例如煙霧監(jiān)測和一氧化碳監(jiān)測。MAXQ3210可直接驅(qū)動(dòng)壓電揚(yáng)聲器，可用非常簡單的軟件實(shí)現(xiàn)這一功能。僅需1位控制位來打開或關(guān)閉壓電揚(yáng)聲器。根據(jù)所選的揚(yáng)聲器不同， MAXQ3210輸出的幅度可以達(dá)到100dB。

    小封裝：MAXQ3210提供小型的24引腳TSSOP封裝。

驅(qū)動(dòng)1-Wire網(wǎng)絡(luò)

    Dallas Semiconductor/Maxim提供一系列使用1-Wire網(wǎng)絡(luò)接口的傳感器和其它器件。該接口的數(shù)據(jù)通信和供電僅需通過一根數(shù)據(jù)線再加一根地線，這意味著微控制器僅需一個(gè)端口即可與1-Wire傳感器通信。

    1-Wire網(wǎng)絡(luò)工作于一主多從模式(多點(diǎn)網(wǎng)絡(luò))。時(shí)序非常靈活，允許從機(jī)以高達(dá)16kbps的速率與主機(jī)通信。每個(gè)1-Wire器件都有一個(gè)全球唯一的64位ROM ID，允許1-Wire主機(jī)精確選擇位于網(wǎng)絡(luò)任何位置的一個(gè)從機(jī)進(jìn)行通信。

    1-Wire總線采用漏極開路模式工作，主機(jī)(或需要輸出數(shù)據(jù)的從機(jī))將數(shù)據(jù)線拉低到地表示數(shù)據(jù)0，將數(shù)據(jù)線釋放為高表示數(shù)據(jù)1。這通常通過在數(shù)據(jù)線和VCC之間連一個(gè)分立電阻實(shí)現(xiàn)，但MAXQ3210的端口引腳支持弱上拉模式，只需將引腳切換到弱上拉模式，數(shù)據(jù)線即可浮高。因此MAXQ3210不需外接電阻。由于主機(jī)和從機(jī)僅需將數(shù)據(jù)線拉低，而從不將數(shù)據(jù)線主動(dòng)拉高，因此數(shù)據(jù)線可以實(shí)現(xiàn)“線-或”功能，這可防止多個(gè)從機(jī)試圖同時(shí)通過1-Wire總線發(fā)送數(shù)據(jù)時(shí)出現(xiàn)沖突。

    為驅(qū)動(dòng)1-Wire網(wǎng)絡(luò)，MAXQ3210利用軟件在一個(gè)引腳上實(shí)現(xiàn)以下類型的時(shí)隙。由于1-Wire所有時(shí)隙由主機(jī)啟動(dòng)，因此當(dāng)MAXQ3210不與從機(jī)通信時(shí)不需要監(jiān)測1-Wire線路。有關(guān)1-Wire時(shí)序的更多詳細(xì)信息請參考DS1822的數(shù)據(jù)資料。

    Reset時(shí)隙寬度大約為1ms。在時(shí)隙的前半部分，主機(jī)(MAXQ3210)將1-Wire總線拉 低，然后主機(jī)將總線釋放，使其浮高?？偩€上的所有1-Wire從機(jī)復(fù)位，并在該時(shí)隙的后半段將總線拉低。這一步產(chǎn)生一個(gè)presence pulse (在線脈沖)，向主機(jī)表明有一個(gè)或多個(gè)1-Wire從機(jī)在線，并且準(zhǔn)備好開始通信。

    Write時(shí)隙大約長120μs，主機(jī)利用這一時(shí)隙向1-Wire從機(jī)發(fā)送0或1。兩種寫時(shí)隙都是以主機(jī)將總線拉低至少1微秒開始。如果發(fā)送1，主機(jī)隨即釋放1-Wire總線(使其浮高)。如果發(fā)送0，主機(jī)在該時(shí)隙剩余的時(shí)間內(nèi)一直將總線拉低。

    Read時(shí)隙大約長60μs，主機(jī)利用這一時(shí)隙讀取從機(jī)發(fā)送的0或1。該時(shí)隙是以主機(jī)將總線拉低至少1微秒開始的。隨后主機(jī)將總線釋放，允許從機(jī)將總線拉低(表示0)，或?qū)⒖偩€釋放使其浮空為高(表示1)。主機(jī)在時(shí)隙中部采樣總線讀取從機(jī)發(fā)送來的數(shù)據(jù)。

    由于MAXQ3210每微秒約等于三個(gè)半指令周期(3.58MHz時(shí)鐘頻率下)，軟件可利用一個(gè)端口引腳(P1.6)方便的實(shí)現(xiàn)1-Wire協(xié)議。

#define OWIN M0[09h].6 ; PI1.6
#define OWOUT M0[01h].6 ; PO1.6
#define OWDIR M0[11h].6 ; PD1.6

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Function : Reset1Wire
;; Description : Sends a standard speed 1-Wire reset pulse on P1.6
;; and checks for a presence pulse reply.
;; Inputs : None
;; Outputs : C - Cleared on success; set on error (no presence
;; pulse detected)
;; Destroys : PSF, LC[0]
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Reset1Wire:
move OWDIR, #1 ; Output mode
move OWOUT, #0 ; Drive low
move LC[0], #RESET_LOW
djnz LC[0], $

move OWOUT, #1 ; Snap high
move LC[0], #SNAP
djnz LC[0], $

move OWDIR, #0 ; Change to weak pullup input
move LC[0], #RESET_PRESAMPLE
djnz LC[0], $

move C, OWIN ; Check for presence detect

move LC[0], #RESET_POSTSAMPLE
djnz LC[0], $

ret

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Function : Write1Wire
;; Description : Writes a standard speed 1-Wire output byte on P1.6.
;; Inputs : GRL - Byte to write to 1-Wire.
;; Outputs : None.
;; Destroys : PSF, AP, APC, A[0], LC[0], LC[1]
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Write1Wire:
move APC, #080h ; Standard mode, select A[0] as Acc
move Acc, GRL
move OWDIR, #1 ; Output drive mode
move LC[1], #8 ; 8 bits to write

Write1Wire_slot:
move OWOUT, #0 ; Drive low for start of write slot

move LC[0], #WRITE_PREBIT
djnz LC[0], $

rrc ; Get the next bit
jump C, Write1Wire_one
Write1Wire_zero:
move OWOUT, #0 ; Keep the line low (zero bit)
jump Write1Wire_next
Write1Wire_one:
move OWOUT, #1
Write1Wire_next:
move LC[0], #WRITE_POSTBIT
djnz LC[0], $ ; Finish the time slot

move OWOUT, #1 ; Drive back high (end of slot)
move LC[0], #WRITE_RECOVERY
djnz LC[0], $ ; Recovery time period

djnz LC[1], Write1Wire_slot

ret

    實(shí)現(xiàn)讀時(shí)隙的功能與之類似。注意，在1-Wire總線上所有數(shù)據(jù)均為低有效位(LSB)先發(fā)。

    利用MAXQ3210實(shí)現(xiàn)1-Wire時(shí)序時(shí)，另一點(diǎn)需要注意的是：盡管1-Wire總線上拉電阻的阻值與總線上的設(shè)備數(shù)有關(guān)，但通常在4k到5k 之間?？墒荕AXQ3210端口引腳上的弱上拉電阻為50k到100k。為了防止1-Wire總線從低電平到高電平轉(zhuǎn)換的時(shí)間過長，演示代碼先將P1.6 輸出設(shè)為短暫的高電平，將總線強(qiáng)制拉高，然后變?yōu)檎５娜跎侠Ｊ?。只要該過程不是在從機(jī)試圖將總線拉低的時(shí)候進(jìn)行，就不會(huì)出現(xiàn)問題。另外，還可以在總線上再加一個(gè)分立的上拉電阻，這樣就可以正常的方式使端口輸出低代表0，輸出三態(tài)代表1。

    注意：當(dāng)構(gòu)建的1-Wire網(wǎng)絡(luò)傳輸距離較遠(yuǎn)或連接的從機(jī)數(shù)量較多時(shí)，還需要注意其他事項(xiàng)。更多信息請參考以下應(yīng)用筆記。

AN148：1-Wire網(wǎng)絡(luò)可靠設(shè)計(jì)指南
AN570：Tech Brief 1 : 1-Wire Net Design Guide
AN937：Book of iButton Standards

用DS1822測量溫度

    盡管MAXQ3210可以使用上面的代碼與大多數(shù)1-Wire從機(jī)器件通信，在本應(yīng)用中我們將主要考慮與 DS1822通信。DS1822是一個(gè)1-Wire從機(jī)器件，可實(shí)現(xiàn)9到12位的攝氏溫度測量，測量結(jié)果可被1-Wire主機(jī)讀取。與多數(shù)1-Wire從機(jī)一樣，DS1822可以完全由1-Wire總線供電，我們稱之為寄生供電。

    DS1822的測量范圍可達(dá)-55°C至+125°C，適用于多數(shù)的室內(nèi)外溫度測量應(yīng)用。溫度分辨率在9位下為0.5°C，12位下0.0625°C。進(jìn)行一次溫度轉(zhuǎn)換所需時(shí)間在低分辨率下約為94ms，在最高分辨率下約為750ms。由于這是一個(gè)簡單應(yīng)用，我們選擇9位分辨率，并忽略最低位(0.5°C)。這樣就可使整個(gè)8位帶符號溫度數(shù)據(jù)與 MAXQ3210的8位累加器匹配。

    所有的1-Wire從機(jī)器件都支持一個(gè)通用指令集，從而使得主機(jī)可以判斷總線上的從機(jī)數(shù)目，讀取ROM ID，并且可以與某一個(gè)從機(jī)或一組從機(jī)進(jìn)行通信。一旦某個(gè)1-Wire從機(jī)被激活，主機(jī)可以針對該從機(jī)類型向其發(fā)送特殊指令。其它所有未被激活的從機(jī)均處于等待狀態(tài)，直到下一個(gè)復(fù)位脈沖出現(xiàn)，才開始再次監(jiān)測1-Wire總線。

    由于在我們的應(yīng)用中總線上僅有一個(gè)1-Wire器件，我們可以使用最簡單的指令集訪問從機(jī)器件，不需要讀取從機(jī)的ROM ID。當(dāng)總線上有多個(gè)從機(jī)器件時(shí)，ROM ID被用來區(qū)分不同的從機(jī)器件。我們的程序中也讀取了一次DS1822的ROM ID，但僅是為了演示。

    我們將使用下面的1-Wire指令集，DS1822支持的其它指令請參考其數(shù)據(jù)資料。

Read ROM [33h]。這一指令假設(shè)1-Wire總線上只有一個(gè)從機(jī)器件。1-Wire 從機(jī)收到該指令后將其8字節(jié)的ROM ID發(fā)回1-Wire主機(jī)。這個(gè)ID包括48位序列號，8位CRC，8位家族碼。家族碼代表器件類型。DS1822的家族碼為22h。收到Read ROM指令后，1-Wire從機(jī)被激活，并響應(yīng)后續(xù)與該從機(jī)器件相關(guān)的指令。

Skip ROM [CCh]。1-Wire總線上有一個(gè)或多個(gè)從機(jī)器件時(shí)都可以使用這一指令。這條指令激活總線上的所有從機(jī)，與從機(jī)的ROM ID無關(guān)。當(dāng)總線上只有一個(gè)從機(jī)時(shí)，可利用這條指令不讀取從機(jī)ID而激活從機(jī)，使其接收后續(xù)相關(guān)指令。當(dāng)總線上有多個(gè)從機(jī)時(shí)，如果使用這條指令，則必須保證后面的指令不會(huì)造成從機(jī)向主機(jī)發(fā)送數(shù)據(jù)。因?yàn)閺臋C(jī)可能發(fā)送不同的數(shù)據(jù)而造成數(shù)據(jù)沖突。

Write Scratchpad [4Eh]。這是DS1822專用的指令，之前先用Read ROM 或Skip ROM指令激活器件。在該指令后1-Wire主機(jī)發(fā)送3字節(jié)的配置數(shù)據(jù)用來配置DS1822，包括溫度轉(zhuǎn)換的位分辨率。更多詳情請參考DS1822的數(shù)據(jù)資料。

Read Scratchpad [BEh]。這也是DS1822專用的指令，該指令允許主機(jī)從DS1822讀取最多9字節(jié)數(shù)據(jù)。這些數(shù)據(jù)包括通過Write Scratchpad指令設(shè)置的配置寄存器值，以及最近的溫度轉(zhuǎn)換結(jié)果。更多詳情請參考DS1822的數(shù)據(jù)資料。我們的應(yīng)用僅需要最開始的兩個(gè)字節(jié)，這兩個(gè)字節(jié)就是最近的溫度轉(zhuǎn)換結(jié)果。

Convert Temperature [44h]。這是DS1822專用的指令。DS1822收到該指令后開始測量溫度，并將其按指定位分辨率轉(zhuǎn)換成數(shù)字量。結(jié)果存儲(chǔ)到兩個(gè)內(nèi)部寄存器中，1-Wire主機(jī)可以通過Read Scratchpad讀取。

當(dāng)執(zhí)行Convert Temperature指令時(shí)，DS1822需要消耗更多的電流(最多1.5mA)，可能超過1-Wire總線弱上拉所能提供的電流。因此，一旦主機(jī)發(fā)出這一指令，必須對1-Wire總線進(jìn)行強(qiáng)上拉，直至溫度轉(zhuǎn)換結(jié)束。在此期間，1-Wire總線上不能有任何通信發(fā)生。MAXQ3210簡單地通過將 P1.6端口從弱上拉切換成輸出高電平來滿足此要求。MAXQ3210端口驅(qū)動(dòng)器能夠輸出足夠DS1822工作所需的電流。

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Function : ConvertAndReadTemp
;; Description : Sends commands to measure temperature and read
;; scratchpad from the DS1822.
;; Inputs : None.
;; Outputs : GRL - 8-bit signed temperature value, in degrees C.
;; Destroys : PSF, AP, APC, A[0], A[1], A[2], LC[0], LC[1]
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

ConvertAndReadTemp:
call Reset1Wire ; Reset the DS1822

move GRL, #OW_SKIP_ROM ; Select the DS1822
call Write1Wire
move GRL, #OW_CONVERT ; Send temp convert command
call Write1Wire

move OWDIR, #1 ; Turn on strong pullup for draw current
move OWOUT, #1

move LC[0], #55 ; About a second
delay:
move LC[1], #0
djnz LC[1], $
djnz LC[0], delay

call Reset1Wire ; Conversion completed; reset again

move GRL, #OW_SKIP_ROM ; Select again
call Write1Wire
move GRL, #OW_RD_SCRATCH ; Read the scratchpad values
call Write1Wire

call Read1Wire
move A[1], GRL ; Temp LSB 3210xxxx
call Read1Wire
move A[2], GRL ; Temp MSB sssss654

move Acc, A[1] ; 3210xxxx
and #0F0h ; 3210----
xchn ; ----3210
move A[1], Acc
move Acc, A[2] ; sssss654
and #00Fh ; ----s654
xchn ; s654----
or A[1] ; s6543210

move GRL, Acc
ret

將測量結(jié)果存儲(chǔ)在數(shù)據(jù)EEPROM中
    為防止1-Wire總線偶然出現(xiàn)數(shù)據(jù)錯(cuò)誤，演示代碼每次測量都執(zhí)行三次溫度轉(zhuǎn)換(A，B和C)，并從中選擇一個(gè)結(jié)果存儲(chǔ)，選擇的依據(jù)為：
如果所有數(shù)據(jù)相同，則存儲(chǔ)該數(shù)據(jù)。

    如果三個(gè)中有兩個(gè)數(shù)據(jù)相同(A = B，B = C或A = C)，則選擇相同的數(shù)據(jù)存儲(chǔ)。
如果沒有數(shù)據(jù)相同，則取中間值存儲(chǔ)。例如，如果(A > B > C)，則存儲(chǔ)B。

    被選中的值被寫入數(shù)據(jù)EEPROM的一個(gè)字中。由于采樣結(jié)果為一個(gè)字節(jié)，每個(gè)字的高字節(jié)被用來指示該記錄(也就是字)是否為空。如果高字節(jié)為0，該記錄/字為空，如果高字節(jié)非0，則低字節(jié)為有效溫度數(shù)據(jù)。這樣就能區(qū)分空記錄和存儲(chǔ)數(shù)據(jù)為0°C的有效數(shù)據(jù)。

;; Two out of three majority vote, or failing that, the measurement
;; in the middle of the three.

move Acc, A[4]
cmp A[5]
jump E, recordTempA ; If (A==B), use that value
cmp A[6]
jump E, recordTempA ; If (A==C), use that value

move Acc, A[5]
cmp A[6]
jump E, recordTempB ; If (B==C), use that value

move Acc, A[4]
sub A[5]
jump S, B_greaterThan_A ; Sign is set if (A-B) is negative

;; If (A > B) {
;; If (C > A) record A (C > A > B)
;; If (B > C) record B, (A > B > C)
;; else record C (A > C > B)

A_greaterThan_B:
move Acc, A[4]
sub A[6] ; A-C
jump S, recordTempA ; Sign is set if (A-C) is negative
move Acc, A[5]
sub A[6] ; B-C
jump S, recordTempC ; Sign is set if (B-C) is negative
jump recordTempB

;; If (B > A) {
;; If (C > B) record B (C > B > A)
;; If (A > C) record B, (A > B > C)
;; else record C (B > C > A)

B_greaterThan_A:
move Acc, A[5]
sub A[6] ; B-C
jump S, recordTempB ; Sign is set if (B-C) is negative
move Acc, A[4]
sub A[6] ; A-C
jump S, recordTempC ; Sign is set if (A-C) is negative
jump recordTempB

recordTempA:
move GRL, A[4]
jump recordTemp

recordTempB:
move GRL, A[5]
jump recordTemp

recordTempC:
move GRL, A[6]
jump recordTemp

recordTemp:
move A[15], GRL

move GRL, #'@'
call TxCharBB
move GR, DP[0]
move GRL, GRH
call TxHexByteBB
move GRL, DP[0]
call TxHexByteBB

move GRL, #' '
call TxCharBB
move GRL, #'W'
call TxCharBB

move GRL, A[15]
call TxHexByteBB

move GRL, A[15] ; Low byte contains temp data
move GRH, #055h ; High byte marks nonzero entry
lcall UROM_loadData ; Write entry to data EEPROM

call IncDP0_EE ; Move to the next entry position
move GR, #0000h ; Erase any data that exists
lcall UROM_loadData ; Erase the oldest entry

    記錄采用循環(huán)方式，從數(shù)據(jù)EEPROM地址020h開始到05Fh結(jié)束，然后再回到開始處。之后每寫入一個(gè)新記錄，將擦除一個(gè)最舊的記錄。當(dāng)通過串行接口向外發(fā)送數(shù)據(jù)時(shí)，應(yīng)用程序通過查找前面是否又有空記錄的方式定位最舊的記錄數(shù)據(jù)。

節(jié)省功耗

    由于本應(yīng)用每分鐘僅記錄一次溫度數(shù)據(jù)，而讀取DS1822數(shù)據(jù)并將其存儲(chǔ)到EEPROM中僅需幾秒鐘。多數(shù)時(shí)間應(yīng)用都在等待一分鐘的延時(shí)結(jié)束。根據(jù)應(yīng)用的要求，不需更改太多代碼即可將溫度記錄間隔拉長，比如到五分鐘、十分鐘或三十分鐘。為了減少等待期間對電池的消耗，應(yīng)盡可能降低功耗。

    MAXQ3210所能提供的最低功耗模式為待機(jī)模式。該模式下，程序停止運(yùn)行，高頻晶振停止工作，電流降到微安量級。由于沒有其它器件還在工作，我們需要將MAXQ3210從待機(jī)模式周期性的喚醒來測量溫度。

    這一要求可通過MAXQ3210的喚醒時(shí)鐘實(shí)現(xiàn)。這一時(shí)鐘依靠在待機(jī)模式仍然工作的內(nèi)部8kHz低電流環(huán)形振蕩器運(yùn)行，能以最長兩分鐘的可編程間隔喚醒微控制器。這種定時(shí)喚醒對于我們的應(yīng)用非常理想，在應(yīng)用中可將“鬧鐘”設(shè)為一分鐘，微控制器工作結(jié)束后接著進(jìn)入待機(jī)模式以節(jié)省功耗，然后等待被喚醒再次采集數(shù)據(jù)。

;; Start the wakeup timer for 60 seconds.

move CKCN.6, #1 ; Select ring oscillator mode
waitRing:
move C, CKCN.5
jump NC, waitRing ; Wait for RGMD=1 (running from ring)

move WUT, #30000 ; 1/8kHz * 30000 * 16 = 60 seconds
move WUTC, #0101b ; Start the wakeup timer (running from ring)

move IV, #wakeUpInt ; Set interrupt handler for wakeup interrupt
move IMR.0, #1 ; Enable interrupts from module 0
move IC.0, #1 ; Globally enable interrupts

move PD0.7, #0 ; Turn off output mode for LED pin
move PO0.7, #1 ; Return to default state (weak pullup)

move CKCN.4, #1 ; Go into Stop mode, wait for wakeup int
nop

jump mainLoop ; Back for another round

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

wakeUpInt:
move PD0.7, #1 ; Turn on output mode for LED port pin
move PO0.7, #0 ; Light the LED

move CKCN.6, #1 ; Select ring oscillator mode
wakeUp_ring:
move C, CKCN.5
jump NC, wakeUp_ring ; Wait for RGMD=1 (running from ring)

move LC[0], #4000
djnz LC[0], $
move PO0.7, #1 ; LED off
move LC[0], #4000
djnz LC[0], $
move WUTC, #0 ; Clear wakeup timer flag

move CKCN.6, #0 ; Select crystal mode
wakeUp_xtal:
move C, CKCN.5
jump C, wakeUp_xtal ; Wait for RGMD=0 (running from crystal)

move GRL, #'W'
call TxCharBB
move GRL, #'U'
call TxCharBB
move GRL, #0Dh
call TxCharBB
move GRL, #0Ah
call TxCharBB

reti

上傳溫度記錄數(shù)據(jù)

    每次上電復(fù)位后，應(yīng)用程序向主機(jī)系統(tǒng)發(fā)送溫度記錄數(shù)據(jù)。數(shù)據(jù)通過10位異步串行接口以9600bps的速率發(fā)送(1位開始位，8位數(shù)據(jù)位，1位停止位)。MAXQ3210不帶硬件UART串口，需要使用一個(gè)端口引腳模擬實(shí)現(xiàn)。由于本應(yīng)用只需發(fā)送，不需接收，所以實(shí)現(xiàn)起來比較簡單。
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Function : TxCharBB
;; Description : Transmits a 10-bit serial character (bit-banged)
;; over P0.0.
;; Inputs : GRL - Character to send
;; Outputs : None
;; Destroys : PSF, AP, APC, A[0], LC[0], LC[1]
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

TxCharBB:
move APC, #080h ; Standard mode, select A[0] as Acc
move Acc, GRL

move PO0.0, #0 ; START bit low
move LC[0], #BITLOOP
djnz LC[0], $

move LC[1], #8 ; 8 bits
TxCharBB_bitLoop:
rrc ; Get the next bit
jump C, TxCharBB_one
TxCharBB_zero:
move PO0.0, #0
sjump TxCharBB_next
TxCharBB_one:
move PO0.0, #1
TxCharBB_next:
move LC[0], #BITLOOP
djnz LC[0], $
djnz LC[1], TxCharBB_bitLoop

move PO0.0, #1 ; STOP bit high
move LC[0], #BITLOOP
djnz LC[0], $
move LC[0], #BITLOOP
djnz LC[0], $

ret

    要把溫度數(shù)據(jù)從帶符號的2進(jìn)制、8位攝氏度數(shù)值轉(zhuǎn)換成容易識(shí)別的ASCII碼、華氏度數(shù)值，還需要增加較多代碼，但這些代碼簡單易懂。使用BCD (二進(jìn)制編碼的十進(jìn)制)運(yùn)算規(guī)則執(zhí)行二進(jìn)制到十進(jìn)制的轉(zhuǎn)換，同時(shí)完成攝氏度到華氏度的轉(zhuǎn)換。

move GR, @DP[0] ; Get the current entry
move Acc, GRH ; Check the high byte
jump Z, endOutput ; If it's zero we're done
move A[15], GRL ; Save the low byte (temp value)

move A[7], #0 ; Hundreds = 0
move A[6], #0 ; Tens = 0
move A[5], #0 ; Ones = 0
move A[4], #0 ; Tenths = 0

move A[3], #0 ; Add 01.8 per degree C
move A[2], #1
move A[1], #8

move Acc, A[15] ; s6543210
jump S, tempNegC

tempPosC:
move GRL, #'+'
jump Z, tempPrint

move LC[0], Acc
tempPosC_loop:
call AddBCD
djnz LC[0], tempPosC_loop

move A[3], #3
move A[2], #2
move A[1], #0 ; Add 32.0
call AddBCD

jump tempPrint

tempNegC:
move GRL, #'-'
neg
jump Z, tempPrint ; Negative zero
jump S, tempPrint ; -128 is outside the sensor range anyhow

move LC[0], Acc
tempNegC_loop:
call AddBCD
djnz LC[0], tempNegC_loop

move A[3], #3
move A[2], #2
move A[1], #0 ; Subtract 32.0
call SubBCD

jump NC, tempPrint
move GRL, #'+' ; Back to positive again
jump tempPrint
tempPrint:
call TxCharBB ; Print plus/minus sign
call TxTempBB ; Print temperature value + newline

call IncDP0_EE ; Move to the next entry

    由于MAXQ3210的端口輸出采用5V電平，在與PC的COM串口連接之前必須使用外部器件(如MAX233ACWP)對輸出進(jìn)行電平轉(zhuǎn)換。完成這一轉(zhuǎn)換后，可以使用任何標(biāo)準(zhǔn)終端仿真程序接收應(yīng)用輸出的數(shù)據(jù)。

RST
DS1822 Detected : 22A9CC15000000E5

+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 59.0
+ 62.6
+ 69.8
+ 59.0
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 55.4
+ 57.2
+ 55.4
+ 55.4
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2
+ 57.2

應(yīng)用功能擴(kuò)展

    MAXQ3210具有1k x 16 (1024字)的EEPROM程序存儲(chǔ)空間，演示代碼只占用了其中的60%至70%。可對應(yīng)用代碼進(jìn)一步優(yōu)化，使其僅占用50%的程序存儲(chǔ)空間。開發(fā)了應(yīng)用的核心功能后，可增加許多額外功能，使其成為功能完備的環(huán)境檢測系統(tǒng)。

    多傳感器?？梢暂p松地?cái)U(kuò)充1-Wire子程序，使其能夠訪問多個(gè)DS1822溫度傳感器，這些傳感器可以分別與單獨(dú)的端口連接(每端口接1個(gè)器件)，或者在單根線上掛一組器件(多點(diǎn)配置)。多點(diǎn)配置結(jié)構(gòu)比較復(fù)雜，但能夠使MAXQ3210連接更多的器件。

    多種傳感器類型。應(yīng)用可以連接多種不同類型的1-Wire傳感器，以測量不同環(huán)境參數(shù)，包括：濕度(DS1923溫度/濕度記錄儀)、物理開關(guān) (DS2401硅序列號)，或使用模數(shù)轉(zhuǎn)換器(DS2450，1-Wire接口、四通道、A/D轉(zhuǎn)換器)的通用傳感器。更多信息見Maxim IC網(wǎng)站的1-Wire/iButton產(chǎn)品頁面。

    聲音告警。MAXQ3210內(nèi)置壓電揚(yáng)聲器驅(qū)動(dòng)電路，因此可以非常簡單地加入高分貝揚(yáng)聲器。當(dāng)溫度轉(zhuǎn)換結(jié)果高于或低于指定門限后，將發(fā)出告警聲。
增加記錄容量。應(yīng)用可以按照寫數(shù)據(jù)EEPROM的方式將數(shù)據(jù)寫到未使用的程序EEPROM中。如果應(yīng)用代碼足夠小，可以用一部分程序EEPROM來存儲(chǔ)更多的溫度轉(zhuǎn)換結(jié)果，進(jìn)而記錄更長時(shí)間的溫度數(shù)據(jù)。

    雙向串行通信。通過位模擬方式實(shí)現(xiàn)雙向串行端口，要比僅僅實(shí)現(xiàn)發(fā)送端口更復(fù)雜，但MAXQ3210仍可輕松實(shí)現(xiàn)。有了雙向端口，主機(jī)可以請求 MAXQ3210上傳記錄數(shù)據(jù)，設(shè)置配置數(shù)據(jù)(如DS1822的溫度分辨率)，按需訪問特定的傳感器，甚至可以通過串行接口更新MAXQ3210的固件。

結(jié)論

    小封裝，低功耗，I/O靈活的MAXQ3210是電池供電的環(huán)境監(jiān)測應(yīng)用的理想選擇。許多1-Wire傳感器可被用來測量溫度、濕度等環(huán)境參數(shù)，而這些傳感器又可僅通過一個(gè)端口實(shí)現(xiàn)與MAX3210的接口。最后，數(shù)據(jù)還可以被存貯在MAXQ3210自帶的非易失EEPROM存儲(chǔ)器中，供以后查詢和分析。