MCS-51單片機(jī)實(shí)用子程序庫

MCS-51單片機(jī)實(shí)用子程序庫

目前已有若干版本的子程序庫公開發(fā)表，它們各有特色。本程序庫中的開平方算法為快速逼近算法，它能達(dá)到牛頓迭代法同樣的精度，而速度加快二十倍左右，超過雙字節(jié)定點(diǎn)除法的速度。

本子程序庫對《單片機(jī)應(yīng)用程序設(shè)計技術(shù)》一書附錄中的子程序庫作了重大修訂：

(1)按當(dāng)前流行的以 IBM PC 為主機(jī)的開發(fā)系統(tǒng)對匯編語言的規(guī)定，讀者不必再進(jìn)行修改，便可直接使用。

(2)對浮點(diǎn)運(yùn)算子程序庫進(jìn)行了進(jìn)一步的測試和優(yōu)化，對十進(jìn)制浮點(diǎn)數(shù)和二進(jìn)制浮點(diǎn)數(shù)的相互轉(zhuǎn)換子程序進(jìn)行了徹底改寫，提高了運(yùn)算精度和可靠性。

(3)新增添了若干個浮點(diǎn)子程序(傳送、比較、清零、判零等)，使編寫數(shù)據(jù)處理程序的工作變得更簡單直觀。

在使用說明中開列了最主要的幾項(xiàng)：標(biāo)號、入口條件、出口信息、影響資源、堆棧需求，各項(xiàng)目的意義請參閱《單片機(jī)應(yīng)用程序設(shè)計技術(shù)》第六章 6.3.7 節(jié)的內(nèi)容。程序清單中開列了四個欄目：標(biāo)號、指令、操作數(shù)、注釋。為方便讀者理解，注釋盡力詳細(xì)。

子程序庫的使用方法如下：

1.將子程序庫全部內(nèi)容鏈接在應(yīng)用程序之后，統(tǒng)一編譯即可。優(yōu)點(diǎn)是簡單方便，缺點(diǎn)是程序太長，大量無關(guān)子程序也包含在其中。

2.僅將子程序庫中的有關(guān)部分內(nèi)容鏈接在應(yīng)用程序之后，統(tǒng)一編譯即可。有些子程序需要調(diào)用一些低級子程序，這些低級子程序也應(yīng)該包含在內(nèi)。優(yōu)點(diǎn)是程序緊湊，缺點(diǎn)是需要對子程序庫進(jìn)行仔細(xì)刪節(jié)。

(一) MCS-51定點(diǎn)運(yùn)算子程序庫及其使用說明

定點(diǎn)運(yùn)算子程序庫文件名為DQ51.ASM，為便于使用，先將有關(guān)約定說明如下：

1.多字節(jié)定點(diǎn)操作數(shù)：用[R0]或[R1]來表示存放在由R0或R1指示的連續(xù)單元中的數(shù)

據(jù)。地址小的單元存放數(shù)據(jù)的高字節(jié)。例如：[R0]=123456H，若(R0)=30H，則(30H)=12H，

(31H)=34H，(32H)=56H。

2.運(yùn)算精度：單次定點(diǎn)運(yùn)算精度為結(jié)果最低位的當(dāng)量值。

3.工作區(qū)：數(shù)據(jù)工作區(qū)固定在PSW、A、B、R2～R7，用戶只要不在工作區(qū)中存放無關(guān)的或非消耗性的信息，程序就具有較好的透明性。

(1) 標(biāo)號： BCDA 功能：多字節(jié)BCD碼加法

入口條件：字節(jié)數(shù)在R7中，被加數(shù)在[R0]中，加數(shù)在[R1]中。

出口信息：和在[R0]中，最高位進(jìn)位在CY中。

影響資源：PSW、A、R2 堆棧需求： 2字節(jié)

BCDA: MOV A,R7 ;取字節(jié)數(shù)至R2中

MOV R2,A

ADD A,R0 ;初始化數(shù)據(jù)指針

MOV R0,A

MOV A,R2

ADD A,R1

MOV R1,A

CLR C

BCD1: DEC R0 ;調(diào)整數(shù)據(jù)指針

DEC R1

MOV A,@R0

ADDC A,@R1 ;按字節(jié)相加

DA A ;十進(jìn)制調(diào)整

MOV @R0,A ;和存回[R0]中

DJNZ R2,BCD1 ;處理完所有字節(jié)

RET

(2) 標(biāo)號： BCDB 功能：多字節(jié)BCD碼減法

入口條件：字節(jié)數(shù)在R7中，被減數(shù)在[R0]中，減數(shù)在[R1]中。

出口信息：差在[R0]中，最高位借位在CY中。

影響資源：PSW、A、R2、R3 堆棧需求： 6字節(jié)

BCDB: LCALL NEG1 ;減數(shù)[R1]十進(jìn)制取補(bǔ)

LCALL BCDA ;按多字節(jié)BCD碼加法處理

CPL C ;將補(bǔ)碼加法的進(jìn)位標(biāo)志轉(zhuǎn)換成借位標(biāo)志

MOV F0,C ;保護(hù)借位標(biāo)志

LCALL NEG1 ;恢復(fù)減數(shù)[R1]的原始值

MOV C,F0 ;恢復(fù)借位標(biāo)志

RET

NEG1: MOV A,R0 ;[R1]十進(jìn)制取補(bǔ)子程序入口

XCH A,R1 ;交換指針

XCH A,R0

LCALL NEG ;通過[R0]實(shí)現(xiàn)[R1]取補(bǔ)

MOV A,R0

XCH A,R1 ;換回指針

XCH A,R0

RET

(3) 標(biāo)號： NEG 功能：多字節(jié)BCD碼取補(bǔ)

入口條件：字節(jié)數(shù)在R7中，操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中。

影響資源：PSW、A、R2、R3 堆棧需求： 2字節(jié)

NEG: MOV A,R7 ;取(字節(jié)數(shù)減一)至R2中

DEC A

MOV R2,A

MOV A,R0 ;保護(hù)指針

MOV R3,A

NEG0: CLR C

MOV A,#99H

SUBB A,@R0 ;按字節(jié)十進(jìn)制取補(bǔ)

MOV @R0,A ;存回[R0]中

INC R0 ;調(diào)整數(shù)據(jù)指針

DJNZ R2,NEG0 ;處理完(R2)字節(jié)

MOV A,#9AH ;最低字節(jié)單獨(dú)取補(bǔ)

SUBB A,@R0

MOV @R0,A

MOV A,R3 ;恢復(fù)指針

MOV R0,A

RET

(4) 標(biāo)號： BRLN 功能：多字節(jié)BCD碼左移十進(jìn)制一位(乘十)

入口條件：字節(jié)數(shù)在R7中，操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中，移出的十進(jìn)制最高位在R3中。

影響資源：PSW、A、R2、R3 堆棧需求： 2字節(jié)

BRLN: MOV A,R7 ;取字節(jié)數(shù)至R2中

MOV R2,A

ADD A,R0 ;初始化數(shù)據(jù)指針

MOV R0,A

MOV R3,#0 ;工作單元初始化

BRL1: DEC R0 ;調(diào)整數(shù)據(jù)指針

MOV A,@R0 ;取一字節(jié)

SWAP A ;交換十進(jìn)制高低位

MOV @R0,A ;存回

MOV A,R3 ;取低字節(jié)移出的十進(jìn)制高位

XCHD A,@R0 ;換出本字節(jié)的十進(jìn)制高位

MOV R3,A ;保存本字節(jié)的十進(jìn)制高位

DJNZ R2,BRL1 ;處理完所有字節(jié)

RET

(5) 標(biāo)號： MULD 功能：雙字節(jié)二進(jìn)制無符號數(shù)乘法

入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。

出口信息：乘積在R2、R3、R4、R5中。

影響資源：PSW、A、B、R2～R7 堆棧需求： 2字節(jié)

MULD: MOV A,R3 ;計算R3乘R7

MOV B,R7

MUL AB

MOV R4,B ;暫存部分積

MOV R5,A

MOV A,R3 ;計算R3乘R6

MOV B,R6

MUL AB

ADD A,R4 ;累加部分積

MOV R4,A

CLR A

ADDC A,B

MOV R3,A

MOV A,R2 ;計算R2乘R7

MOV B,R7

MUL AB

ADD A,R4 ;累加部分積

MOV R4,A

MOV A,R3

ADDC A,B

MOV R3,A

CLR A

RLC A

XCH A,R2 ;計算R2乘R6

MOV B,R6

MUL AB

ADD A,R3 ;累加部分積

MOV R3,A

MOV A,R2[!--empirenews.page--]

ADDC A,B

MOV R2,A

RET

(6) 標(biāo)號： MUL2 功能：雙字節(jié)二進(jìn)制無符號數(shù)平方

入口條件：待平方數(shù)在R2、R3中。

出口信息：結(jié)果在R2、R3、R4、R5中。

影響資源：PSW、A、B、R2～R5 堆棧需求： 2字節(jié)

MUL2: MOV A,R3 ;計算R3平方

MOV B,A

MUL AB

MOV R4,B ;暫存部分積

MOV R5,A

MOV A,R2 ;計算R2平方

MOV B,A

MUL AB

XCH A,R3 ;暫存部分積，并換出R2和R3

XCH A,B

XCH A,R2

MUL AB ;計算2×R2×R3

CLR C

RLC A

XCH A,B

RLC A

JNC MU20

INC R2 ;累加溢出量

MU20: XCH A,B ;累加部分積

ADD A,R4

MOV R4,A

MOV A,R3

ADDC A,B

MOV R3,A

CLR A

ADDC A,R2

MOV R2,A

RET

(7) 標(biāo)號： DIVD 功能：雙字節(jié)二進(jìn)制無符號數(shù)除法

入口條件：被除數(shù)在R2、R3、R4、R5中，除數(shù)在R6、R7中。

出口信息：OV=0 時，雙字節(jié)商在R2、R3中，OV=1 時溢出。

影響資源：PSW、A、B、R1～R7 堆棧需求： 2字節(jié)

DIVD: CLR C ;比較被除數(shù)和除數(shù)

MOV A,R3

SUBB A,R7

MOV A,R2

SUBB A,R6

JC DVD1

SETB OV ;溢出

RET

DVD1: MOV B,#10H ;計算雙字節(jié)商

DVD2: CLR C ;部分商和余數(shù)同時左移一位

MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

XCH A,R2

RLC A

XCH A,R2

MOV F0,C ;保存溢出位

CLR C

SUBB A,R7 ;計算(R2R3-R6R7)

MOV R1,A

MOV A,R2

SUBB A,R6

ANL C,/F0 ;結(jié)果判斷

JC DVD3

MOV R2,A ;夠減，存放新的余數(shù)

MOV A,R1

MOV R3,A

INC R5 ;商的低位置一

DVD3: DJNZ B,DVD2 ;計算完十六位商(R4R5)

MOV A,R4 ;將商移到R2R3中

MOV R2,A

MOV A,R5

MOV R3,A

CLR OV ;設(shè)立成功標(biāo)志

RET

(8) 標(biāo)號： D457 功能：雙字節(jié)二進(jìn)制無符號數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件：被除數(shù)在R4、R5中，除數(shù)在R7中。

出口信息：OV=0 時，單字節(jié)商在R3中，OV=1 時溢出。

影響資源：PSW、A、R3～R7 堆棧需求： 2字節(jié)

D457: CLR C

MOV A,R4

SUBB A,R7

JC DV50

SETB OV ;商溢出

RET

DV50: MOV R6,#8 ;求平均值(R4R5/R7-→R3)

DV51: MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV F0,C

CLR C

SUBB A,R7

ANL C,/F0

JC DV52

MOV R4,A

DV52: CPL C

MOV A,R3

RLC A

MOV R3,A

DJNZ R6,DV51

MOV A,R4 ;四舍五入

ADD A,R4

JC DV53

SUBB A,R7

JC DV54

DV53: INC R3

DV54: CLR OV

RET

(9) 標(biāo)號： DV31 功能：三字節(jié)二進(jìn)制無符號數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件：被除數(shù)在R3、R4、R5中，除數(shù)在R7中。

出口信息：OV=0 時，雙字節(jié)商在R4、R5中，OV=1 時溢出。

影響資源：PSW、A、B、R2～R7 堆棧需求： 2字節(jié)

DV31: CLR C

MOV A,R3

SUBB A,R7

JC DV30

SETB OV ;商溢出

RET

DV30: MOV R2,#10H ;求R3R4R5/R7-→R4R5

DM23: CLR C

MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

MOV F0,C

CLR C

SUBB A,R7

ANL C,/F0

JC DM24

MOV R3,A

INC R5

DM24: DJNZ R2,DM23

MOV A,R3 ;四舍五入

ADD A,R3

JC DM25

SUBB A,R7

JC DM26

DM25: INC R5

MOV A,R5

JNZ DM26

INC R4

DM26: CLR OV

RET ;商在R4R5中

(10) 標(biāo)號： MULS 功能：雙字節(jié)二進(jìn)制有符號數(shù)乘法(補(bǔ)碼)

入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。

出口信息：乘積在R2、R3、R4、R5中。

影響資源：PSW、A、B、R2～R7 堆棧需求： 4字節(jié)

MULS: MOV R4,#0 ;清零R4R5

MOV R5,#0

LCALL MDS ;計算結(jié)果的符號和兩個操作數(shù)的絕對值

LCALL MULD ;計算兩個絕對值的乘積

SJMP MDSE ;用補(bǔ)碼表示結(jié)果

(11) 標(biāo)號： DIVS 功能：雙字節(jié)二進(jìn)制有符號數(shù)除法(補(bǔ)碼)

入口條件：被除數(shù)在R2、R3、R4、R5中，除數(shù)在R6、R7中。

出口信息：OV=0時商在R2、R3中，OV=1時溢出。

影響資源：PSW、A、B、R1～R7 堆棧需求： 5字節(jié)

DIVS: LCALL MDS ;計算結(jié)果的符號和兩個操作數(shù)的絕對值

PUSH PSW ;保存結(jié)果的符號

LCALL DIVD ;計算兩個絕對值的商

JNB OV,DVS1 ;溢出否?

POP ACC ;溢出，放去結(jié)果的符號，保留溢出標(biāo)志

RET

DVS1: POP PSW ;未溢出，取出結(jié)果的符號

MOV R4,#0

MOV R5,#0

MDSE: JB F0,MDS2 ;用補(bǔ)碼表示結(jié)果

CLR OV ;結(jié)果為正，原碼即補(bǔ)碼，計算成功

RET

MDS: CLR F0 ;結(jié)果符號初始化

MOV A,R6 ;判斷第二操作數(shù)的符號

JNB ACC.7,MDS1;為正，不必處理

CPL F0 ;為負(fù)，結(jié)果符號取反

XCH A,R7 ;第二操作數(shù)取補(bǔ)，得到其絕對值

CPL A

ADD A,#1

XCH A,R7

CPL A

ADDC A,#0

MOV R6,A

MDS1: MOV A,R2 ;判斷第一操作數(shù)或運(yùn)算結(jié)果的符號[!--empirenews.page--]

JNB ACC.7,MDS3;為正，不必處理

CPL F0 ;為負(fù)，結(jié)果符號取反

MDS2: MOV A,R5 ;求第一操作數(shù)的絕對值或運(yùn)算結(jié)果的補(bǔ)碼

CPL A

ADD A,#1

MOV R5,A

MOV A,R4

CPL A

ADDC A,#0

MOV R4,A

MOV A,R3

CPL A

ADDC A,#0

MOV R3,A

MOV A,R2

CPL A

ADDC A,#0

MOV R2,A

MDS3: CLR OV ;運(yùn)算成功

RET

(12) 標(biāo)號： SH2 功能：雙字節(jié)二進(jìn)制無符號數(shù)開平方(快速)

入口條件：被開方數(shù)在R2、R3中。

出口信息：平方根仍在R2、R3中，整數(shù)部分的位數(shù)為原數(shù)的一半，其余為小數(shù)。

影響資源：PSW、A、B、R2～R7 堆棧需求： 2字節(jié)

SH2: MOV A,R2

ORL A,R3

JNZ SH20

RET ;被開方數(shù)為零，不必運(yùn)算

SH20: MOV R7,#0 ;左規(guī)次數(shù)初始化

MOV A,R2

SH22: ANL A,#0C0H ;被開方數(shù)高字節(jié)小于40H否?

JNZ SQRH ;不小于40H，左規(guī)格化完成，轉(zhuǎn)開方過程

CLR C ;每左規(guī)一次，被開方數(shù)左移兩位

MOV A,R3

RLC A

MOV F0,C

CLR C

RLC A

MOV R3,A

MOV A,R2

MOV ACC.7,C

MOV C,F0

RLC A

RLC A

MOV R2,A

INC R7 ;左規(guī)次數(shù)加一

SJMP SH22 ;繼續(xù)左規(guī)

(13) 標(biāo)號： SH4 功能：四字節(jié)二進(jìn)制無符號數(shù)開平方(快速)

入口條件：被開方數(shù)在R2、R3、R4、R5中。

出口信息：平方根在R2、R3中，整數(shù)部分的位數(shù)為原數(shù)的一半，其余為小數(shù)。

影響資源：PSW、A、B、R2～R7 堆棧需求： 2字節(jié)

SH4: MOV A,R2

ORL A,R3

ORL A,R4

ORL A,R5

JNZ SH40

RET ;被開方數(shù)為零，不必運(yùn)算

SH40: MOV R7,#0 ;左規(guī)次數(shù)初始化

MOV A,R2

SH41: ANL A,#0C0H ;被開方數(shù)高字節(jié)小于40H否?

JNZ SQRH ;不小于40H，左規(guī)格化完成

MOV R6,#2 ;每左規(guī)一次，被開方數(shù)左移兩位

SH42: CLR C ;被開方數(shù)左移一位

MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

MOV A,R2

RLC A

MOV R2,A

DJNZ R6,SH42 ;被開方數(shù)左移完兩位

INC R7 ;左規(guī)次數(shù)加一

SJMP SH41 ;繼續(xù)左規(guī)

SQRH: MOV A,R2 ;規(guī)格化后高字節(jié)按折線法分為三個區(qū)間

ADD A,#57H

JC SQR2

ADD A,#45H

JC SQR1

ADD A,#24H

MOV B,#0E3H ;第一區(qū)間的斜率

MOV R4,#80H ;第一區(qū)間的平方根基數(shù)

SJMP SQR3

SQR1: MOV B,#0B2H ;第二區(qū)間的斜率

MOV R4,#0A0H;第二區(qū)間的平方根基數(shù)

SJMP SQR3

SQR2: MOV B,#8DH ;第三區(qū)間的斜率

MOV R4,#0D0H;第三區(qū)間的平方根基數(shù)

SQR3: MUL AB ;與區(qū)間基點(diǎn)的偏移量乘區(qū)間斜率

MOV A,B

ADD A,R4 ;累加到平方根的基數(shù)上

MOV R4,A

MOV B,A

MUL AB ;求當(dāng)前平方根的冪

XCH A,R3 ;求偏移量(存放在R2R3中)

CLR C

SUBB A,R3

MOV R3,A

MOV A,R2

SUBB A,B

MOV R2,A

SQR4: SETB C ;用減奇數(shù)法校正一個字節(jié)的平方根

MOV A,R4 ;當(dāng)前平方根的兩倍加一存入R5R6中

RLC A

MOV R6,A

CLR A

RLC A

MOV R5,A

MOV A,R3 ;偏移量小于該奇數(shù)否?

SUBB A,R6

MOV B,A

MOV A,R2

SUBB A,R5

JC SQR5 ;小于，校正結(jié)束，已達(dá)到一個字節(jié)的精度

INC R4 ;不小于，平方根加一

MOV R2,A ;保存新的偏移量

MOV R3,B

SJMP SQR4 ;繼續(xù)校正

SQR5: MOV A,R4 ;將一個字節(jié)精度的根存入R2

XCH A,R2

RRC A

MOV F0,C ;保存最終偏移量的最高位

MOV A,R3

MOV R5,A ;將最終偏移量的低八位存入R5中

MOV R4,#8 ;通過(R5R6/R2)求根的低字節(jié)

SQR6: CLR C

MOV A,R3

RLC A

MOV R3,A

CLR C

MOV A,R5

SUBB A,R2

JB F0,SQR7

JC SQR8

SQR7: MOV R5,A

INC R3

SQR8: CLR C

MOV A,R5

RLC A

MOV R5,A

MOV F0,C

DJNZ R4,SQR6 ;根的第二字節(jié)計算完，在R3中

MOV A,R7 ;取原被開方數(shù)的左規(guī)次數(shù)

JZ SQRE ;未左規(guī)，開方結(jié)束

SQR9: CLR C ;按左規(guī)次數(shù)右移平方根，得到實(shí)際根

MOV A,R2

RRC A

MOV R2,A

MOV A,R3

RRC A

MOV R3,A

DJNZ R7,SQR9

SQRE: RET

(14) 標(biāo)號： HASC 功能：單字節(jié)十六進(jìn)制數(shù)轉(zhuǎn)換成雙字節(jié)ASCII碼

入口條件：待轉(zhuǎn)換的單字節(jié)十六進(jìn)制數(shù)在累加器A中。

出口信息：高四位的ASCII碼在A中，低四位的ASCII碼在B中。

影響資源：PSW、A、B 堆棧需求： 4字節(jié)

HASC: MOV B,A ;暫存待轉(zhuǎn)換的單字節(jié)十六進(jìn)制數(shù)

LCALL HAS1 ;轉(zhuǎn)換低四位

XCH A,B ;存放低四位的ASCII碼

SWAP A ;準(zhǔn)備轉(zhuǎn)換高四位

HAS1: ANL A,#0FH ;將累加器的低四位轉(zhuǎn)換成ASCII碼

ADD A,#90H

DA A

ADDC A,#40H

DA A

RET

(15) 標(biāo)號： ASCH 功能：ASCII碼轉(zhuǎn)換成十六進(jìn)制數(shù)

入口條件：待轉(zhuǎn)換的ASCII碼(30H～39H或41H～46H)在A中。

出口信息：轉(zhuǎn)換后的十六進(jìn)制數(shù)(00H～0FH)仍在累加器A中。

影響資源：PSW、A 堆棧需求： 2字節(jié)

ASCH: CLR C

SUBB A,#30H

JNB ACC.4,ASH1

SUBB A,#7

ASH1: RET

(16) 標(biāo)號：HBCD 功能：單字節(jié)十六進(jìn)制整數(shù)轉(zhuǎn)換成單字節(jié)BCD碼整數(shù)[!--empirenews.page--]

入口條件：待轉(zhuǎn)換的單字節(jié)十六進(jìn)制整數(shù)在累加器A中。

出口信息：轉(zhuǎn)換后的BCD碼整數(shù)(十位和個位)仍在累加器A中，百位在R3中。

影響資源：PSW、A、B、R3 堆棧需求： 2字節(jié)

HBCD: MOV B,#100 ;分離出百位，存放在R3中

DIV AB

MOV R3,A

MOV A,#10 ;余數(shù)繼續(xù)分離十位和個位

XCH A,B

DIV AB

SWAP A

ORL A,B ;將十位和個位拼裝成BCD碼

RET

(17) 標(biāo)號： HB2 功能：雙字節(jié)十六進(jìn)制整數(shù)轉(zhuǎn)換成雙字節(jié)BCD碼整數(shù)

入口條件：待轉(zhuǎn)換的雙字節(jié)十六進(jìn)制整數(shù)在R6、R7中。

出口信息：轉(zhuǎn)換后的三字節(jié)BCD碼整數(shù)在R3、R4、R5中。

影響資源：PSW、A、R2～R7 堆棧需求： 2字節(jié)

HB2: CLR A ;BCD碼初始化

MOV R3,A

MOV R4,A

MOV R5,A

MOV R2,#10H ;轉(zhuǎn)換雙字節(jié)十六進(jìn)制整數(shù)

HB3: MOV A,R7 ;從高端移出待轉(zhuǎn)換數(shù)的一位到CY中

RLC A

MOV R7,A

MOV A,R6

RLC A

MOV R6,A

MOV A,R5 ;BCD碼帶進(jìn)位自身相加，相當(dāng)于乘2

ADDC A,R5

DA A ;十進(jìn)制調(diào)整

MOV R5,A

MOV A,R4

ADDC A,R4

DA A

MOV R4,A

MOV A,R3

ADDC A,R3

MOV R3,A ;雙字節(jié)十六進(jìn)制數(shù)的萬位數(shù)不超過6，不用調(diào)整

DJNZ R2,HB3 ;處理完16bit

RET

(18) 標(biāo)號： HBD 功能：單字節(jié)十六進(jìn)制小數(shù)轉(zhuǎn)換成單字節(jié)BCD碼小數(shù)

入口條件：待轉(zhuǎn)換的單字節(jié)十六進(jìn)制小數(shù)在累加器A中。

出口信息：CY=0時轉(zhuǎn)換后的BCD碼小數(shù)仍在A中。CY=1時原小數(shù)接近整數(shù)1。

影響資源：PSW、A、B 堆棧需求： 2字節(jié)

HBD: MOV B,#100 ;原小數(shù)擴(kuò)大一百倍

MUL AB

RLC A ;余數(shù)部分四舍五入

CLR A

ADDC A,B

MOV B,#10 ;分離出十分位和百分位

DIV AB

SWAP A

ADD A,B ;拼裝成單字節(jié)BCD碼小數(shù)

DA A ;調(diào)整后若有進(jìn)位，原小數(shù)接近整數(shù)1

RET

(19) 標(biāo)號： HBD2 功能：雙字節(jié)十六進(jìn)制小數(shù)轉(zhuǎn)換成雙字節(jié)BCD碼小數(shù)

入口條件：待轉(zhuǎn)換的雙字節(jié)十六進(jìn)制小數(shù)在R2、R3中。

出口信息：轉(zhuǎn)換后的雙字節(jié)BCD碼小數(shù)仍在R2、R3中。

影響資源：PSW、A、B、R2、R3、R4、R5 堆棧需求： 6字節(jié)

HBD2: MOV R4,#4 ;四位十進(jìn)制碼

HBD3: MOV A,R3 ;原小數(shù)擴(kuò)大十倍

MOV B,#10

MUL AB

MOV R3,A

MOV R5,B

MOV A,R2

MOV B,#10

MUL AB

ADD A,R5

MOV R2,A

CLR A

ADDC A,B

PUSH ACC ;保存溢出的一位十進(jìn)制碼

DJNZ R4,HBD3 ;計算完四位十進(jìn)制碼

POP ACC ;取出萬分位

MOV R3,A

POP ACC ;取出千分位

SWAP A

ORL A,R3 ;拼裝成低字節(jié)BCD碼小數(shù)

MOV R3,A

POP ACC ;取出百分位

MOV R2,A

POP ACC ;取出十分位

SWAP A

ORL A,R2 ;拼裝成高字節(jié)BCD碼小數(shù)

MOV R2,A

RET

(20)標(biāo)號：BCDH 功能：單字節(jié)BCD碼整數(shù)轉(zhuǎn)換成單字節(jié)十六進(jìn)制整數(shù)

入口條件：待轉(zhuǎn)換的單字節(jié)BCD碼整數(shù)在累加器A中。

出口信息：轉(zhuǎn)換后的單字節(jié)十六進(jìn)制整數(shù)仍在累加器A中。

影響資源：PSW、A、B、R4 堆棧需求： 2字節(jié)

BCDH: MOV B,#10H ;分離十位和個位

DIV AB

MOV R4,B ;暫存?zhèn)€位

MOV B,#10 ;將十位轉(zhuǎn)換成十六進(jìn)制

MUL AB

ADD A,R4 ;按十六進(jìn)制加上個位

RET

(21)標(biāo)號： BH2 功能：雙字節(jié)BCD碼整數(shù)轉(zhuǎn)換成雙字節(jié)十六進(jìn)制整數(shù)

入口條件：待轉(zhuǎn)換的雙字節(jié)BCD碼整數(shù)在R2、R3中。

出口信息：轉(zhuǎn)換后的雙字節(jié)十六進(jìn)制整數(shù)仍在R2、R3中。

影響資源：PSW、A、B、R2、R3、R4 堆棧需求： 4字節(jié)

BH2: MOV A,R3 ;將低字節(jié)轉(zhuǎn)換成十六進(jìn)制

LCALL BCDH

MOV R3,A

MOV A,R2 ;將高字節(jié)轉(zhuǎn)換成十六進(jìn)制

LCALL BCDH

MOV B,#100 ;擴(kuò)大一百倍

MUL AB

ADD A,R3 ;和低字節(jié)按十六進(jìn)制相加

MOV R3,A

CLR A

ADDC A,B

MOV R2,A

RET

(22)標(biāo)號： BHD 功能：單字節(jié)BCD碼小數(shù)轉(zhuǎn)換成單字節(jié)十六進(jìn)制小數(shù)

入口條件：待轉(zhuǎn)換的單字節(jié)BCD碼數(shù)在累加器A中。

出口信息：轉(zhuǎn)換后的單字節(jié)十六進(jìn)制小數(shù)仍在累加器A中。

影響資源：PSW、A、R2、R3 堆棧需求： 2字節(jié)

BHD: MOV R2,#8 ;準(zhǔn)備計算一個字節(jié)小數(shù)

BHD0: ADD A,ACC ;按十進(jìn)制倍增

DA A

XCH A,R3

RLC A ;將進(jìn)位標(biāo)志移入結(jié)果中

XCH A,R3

DJNZ R2,BHD0 ;共計算8bit小數(shù)

ADD A,#0B0H ;剩余部分達(dá)到0.50否?

JNC BHD1 ;四舍

INC R3 ;五入

BHD1: MOV A,R3 ;取結(jié)果

RET

(23)標(biāo)號： BHD2 功能：雙字節(jié)BCD碼小數(shù)轉(zhuǎn)換成雙字節(jié)十六進(jìn)制小數(shù)

入口條件：待轉(zhuǎn)換的雙字節(jié)BCD碼小數(shù)在R4、R5中。

出口信息：轉(zhuǎn)換后的雙字節(jié)十六進(jìn)制小數(shù)在R2、R3中。*

影響資源：PSW、A、R2～R6 堆棧需求： 2字節(jié)

BHD2: MOV R6,#10H ;準(zhǔn)備計算兩個字節(jié)小數(shù)

BHD3: MOV A,R5 ;按十進(jìn)制倍增

ADD A,R5

DA A

MOV R5,A

MOV A,R4

ADDC A,R4

DA A

MOV R4,A

MOV A,R3 ;將進(jìn)位標(biāo)志移入結(jié)果中

RLC A

MOV R3,A

MOV A,R2

RLC A

MOV R2,A

DJNZ R6,BHD3 ;共計算16bit小數(shù)

MOV A,R4

ADD A,#0B0H ;剩余部分達(dá)到0.50否?

JNC BHD4 ;四舍

INC R3 ;五入

MOV A,R3

JNZ BHD4

INC R2

BHD4: RET

(24) 標(biāo)號： MM 功能：求單字節(jié)十六進(jìn)制無符號數(shù)據(jù)塊的極值

入口條件：數(shù)據(jù)塊的首址在DPTR中，數(shù)據(jù)個數(shù)在R7中。[!--empirenews.page--]

出口信息：最大值在R6中，地址在R2R3中;最小值在R7中，地址在R4R5中。

影響資源：PSW、A、B、R1～R7 堆棧需求： 4字節(jié)

MM: MOV B,R7 ;保存數(shù)據(jù)個數(shù)

MOVX A,@DPTR ;讀取第一個數(shù)據(jù)

MOV R6,A ;作為最大值的初始值

MOV R7,A ;也作為最小值的初始值

MOV A,DPL ;取第一個數(shù)據(jù)的地址

MOV R3,A ;作為最大值存放地址的初始值

MOV R5,A ;也作為最小值存放地址的初始值

MOV A,DPH

MOV R2,A

MOV R4,A

MOV A,B ;取數(shù)據(jù)個數(shù)

DEC A ;減一，得到需要比較的次數(shù)

JZ MME ;只有一個數(shù)據(jù)，不需要比較

MOV R1,A ;保存比較次數(shù)

PUSH DPL ;保護(hù)數(shù)據(jù)塊的首址

PUSH DPH

MM1: INC DPTR ;指向一個新的數(shù)據(jù)

MOVX A,@DPTR ;讀取這個數(shù)據(jù)

MOV B,A ;保存

SETB C ;與最大值比較

SUBB A,R6

JC MM2 ;不超過當(dāng)前最大值，保持當(dāng)前最大值

MOV R6,B ;超過當(dāng)前最大值，更新最大值存放地址

MOV R2,DPH ;同時更新最大值存放地址

MOV R3,DPL

SJMP MM3

MM2: MOV A,B ;與最小值比較

CLR C

SUBB A,R7

JNC MM3 ;大于或等于當(dāng)前最小值，保持當(dāng)前最小值

MOV R7,B ;更新最小值

MOV R4,DPH ;更新最小值存放地址

MOV R5,DPL

MM3: DJNZ R1,MM1 ;處理完全部數(shù)據(jù)

POP DPH ;恢復(fù)數(shù)據(jù)首址

POP DPL

MME: RET

(25) 標(biāo)號： MMS 功能：求單字節(jié)十六進(jìn)制有符號數(shù)據(jù)塊的極值

入口條件：數(shù)據(jù)塊的首址在DPTR中，數(shù)據(jù)個數(shù)在R7中。

出口信息：最大值在R6中， 地址在R2R3中;最小值在R7中，地址在R4R5中。

影響資源：PSW、A、B、R1～R7 堆棧需求： 4字節(jié)

MMS: MOV B,R7 ;保存數(shù)據(jù)個數(shù)

MOVX A,@DPTR ;讀取第一個數(shù)據(jù)

MOV R6,A ;作為最大值的初始值

MOV R7,A ;也作為最小值的初始值

MOV A,DPL ;取第一個數(shù)據(jù)的地址

MOV R3,A ;作為最大值存放地址的初始值

MOV R5,A ;也作為最小值存放地址的初始值

MOV A,DPH

MOV R2,A

MOV R4,A

MOV A,B ;取數(shù)據(jù)個數(shù)

DEC A ;減一，得到需要比較的次數(shù)

JZ MMSE ;只有一個數(shù)據(jù)，不需要比較

MOV R1,A ;保存比較次數(shù)

PUSH DPL ;保護(hù)數(shù)據(jù)塊的首址

PUSH DPH

MMS1: INC DPTR ;調(diào)整數(shù)據(jù)指針

MOVX A,@DPTR ;讀取一個數(shù)據(jù)

MOV B,A ;保存

SETB C ;與最大值比較

SUBB A,R6

JZ MMS4 ;相同，不更新最大值

JNB OV,MMS2 ;差未溢出，符號位有效

CPL ACC.7 ;差溢出，符號位取反

MMS2: JB ACC.7,MMS4;差為負(fù)，不更新最大值

MOV R6,B ;更新最大值

MOV R2,DPH ;更新最大值存放地址

MOV R3,DPL

SJMP MMS7

MMS4: MOV A,B ;與最小值比較

CLR C

SUBB A,R7

JNB OV,MMS6 ;差未溢出，符號位有效

CPL ACC.7 ;差溢出，符號位取反

MMS6: JNB ACC.7,MMS7;差為正，不更新最小值

MOV R7,B ;更新最小值

MOV R4,DPH ;更新最小值存放地址

MOV R5,DPL

MMS7: DJNZ R1,MMS1 ;處理完全部數(shù)據(jù)

POP DPH ;恢復(fù)數(shù)據(jù)首址

POP DPL

MMSE: RET

(26) 標(biāo)號： FDS1 功能：順序查找(ROM)單字節(jié)表格

入口條件：待查找的內(nèi)容在A中，表格首址在DPTR中，表格的字節(jié)數(shù)在R7中。

出口信息：OV=0時，順序號在累加器A中;OV=1時，未找到。

影響資源：PSW、A、B、R2、R6 堆棧需求： 2字節(jié)

FDS1: MOV B,A ;保存待查找的內(nèi)容

MOV R2,#0 ;順序號初始化(指向表首)

MOV A,R7 ;保存表格的長度

MOV R6,A

FD11: MOV A,R2 ;按順序號讀取表格內(nèi)容

MOVC A,@A+DPTR

CJNE A,B,FD12;與待查找的內(nèi)容比較

CLR OV ;相同，查找成功

MOV A,R2 ;取對應(yīng)的順序號

RET

FD12: INC R2 ;指向表格中的下一個內(nèi)容

DJNZ R6,FD11 ;查完全部表格內(nèi)容

SETB OV ;未查找到，失敗

RET

(27) 標(biāo)號： FDS2 功能：順序查找(ROM)雙字節(jié)表格

入口條件：查找內(nèi)容在R4、R5中，表格首址在DPTR中，數(shù)據(jù)總個數(shù)在R7中。

出口信息：OV=0時順序號在累加器A中，地址在DPTR中;OV=1時未找到。

影響資源：PSW、A、R2、R6、DPTR 堆棧需求： 2字節(jié)

FDS2: MOV A,R7 ;保存表格中數(shù)據(jù)的個數(shù)

MOV R6,A

MOV R2,#0 ;順序號初始化(指向表首)

FD21: CLR A ;讀取表格內(nèi)容的高字節(jié)

MOVC A,@A+DPTR

XRL A,R4 ;與待查找內(nèi)容的高字節(jié)比較

JNZ FD22

MOV A,#1 ;讀取表格內(nèi)容的低字節(jié)

MOVC A,@A+DPTR

XRL A,R5 ;與待查找內(nèi)容的低字節(jié)比較

JNZ FD22

CLR OV ;相同，查找成功

MOV A,R2 ;取對應(yīng)的順序號

RET

FD22: INC DPTR ;指向下一個數(shù)據(jù)

INC DPTR

INC R2 ;順序號加一

DJNZ R6,FD21 ;查完全部數(shù)據(jù)

SETB OV ;未查找到，失敗

RET

(28) 標(biāo)號：FDD1 功能：對分查找(ROM)單字節(jié)無符號增序數(shù)據(jù)表格

入口條件：待查找的內(nèi)容在累加器A中，表格首址在DPTR中，字節(jié)數(shù)在R7中。

出口信息：OV=0 時，順序號在累加器A中;OV=1 時，未找到。

影響資源：PSW、A、B、R2、R3、R4 堆棧需求： 2字節(jié)

FDD1: MOV B,A ;保存待查找的內(nèi)容

MOV R2,#0 ;區(qū)間低端指針初始化(指向第一個數(shù)據(jù))

MOV A,R7

DEC A

MOV R3,A ;區(qū)間高端指針初始化(指向最后一個數(shù)據(jù))

FD61: CLR C ;判斷區(qū)間大小

MOV A,R3

SUBB A,R2

JC FD69 ;區(qū)間消失，查找失敗

RRC A ;取區(qū)間大小的一半

ADD A,R2 ;加上區(qū)間的低端[!--empirenews.page--]

MOV R4,A ;得到區(qū)間的中心

MOVC A,@A+DPTR;讀取該點(diǎn)的內(nèi)容

CJNE A,B,FD65;與待查找的內(nèi)容比較

CLR OV ;相同，查找成功

MOV A,R4 ;取順序號

RET

FD65: JC FD68 ;該點(diǎn)的內(nèi)容比待查找的內(nèi)容大否?

MOV A,R4 ;偏大，取該點(diǎn)位置

DEC A ;減一

MOV R3,A ;作為新的區(qū)間高端

SJMP FD61 ;繼續(xù)查找

FD68: MOV A,R4 ;偏小，取該點(diǎn)位置

INC A ;加一

MOV R2,A ;作為新的區(qū)間低端

SJMP FD61 ;繼續(xù)查找

FD69: SETB OV ;查找失敗

RET

(29) 標(biāo)號：FDD2 功能：對分查找(ROM)雙字節(jié)無符號增序數(shù)據(jù)表格

入口條件：查找內(nèi)容在R4、R5中，表格首址在DPTR中，數(shù)據(jù)個數(shù)在R7中。

出口信息：OV=0 時順序號在累加器A中，址在DPTR中;OV=1 時未找到。

影響資源：PSW、A、B、R1～R7、DPTR 堆棧需求： 2字節(jié)

FDD2: MOV R2,#0 ;區(qū)間低端指針初始化(指向第一個數(shù)據(jù))

MOV A,R7

DEC A

MOV R3,A ;區(qū)間高端指針初始化，指向最后一個數(shù)據(jù)

MOV R6,DPH ;保存表格首址

MOV R7,DPL

FD81: CLR C ;判斷區(qū)間大小

MOV A,R3

SUBB A,R2

JC FD89 ;區(qū)間消失，查找失敗

RRC A ;取區(qū)間大小的一半

ADD A,R2 ;加上區(qū)間的低端

MOV R1,A ;得到區(qū)間的中心

MOV DPH,R6

CLR C ;計算區(qū)間中心的地址

RLC A

JNC FD82

INC DPH

FD82: ADD A,R7

MOV DPL,A

JNC FD83

INC DPH

FD83: CLR A ;讀取該點(diǎn)的內(nèi)容的高字節(jié)

MOVC A,@A+DPTR

MOV B,R4 ;與待查找內(nèi)容的高字節(jié)比較

CJNE A,B,FD84;不相同

MOV A,#1 ;讀取該點(diǎn)的內(nèi)容的低字節(jié)

MOVC A,@A+DPTR

MOV B,R5

CJNE A,B,FD84;與待查找內(nèi)容的低字節(jié)比較

MOV A,R1 ;取順序號

CLR OV ;查找成功

RET

FD84: JC FD86 ;該點(diǎn)的內(nèi)容比待查找的內(nèi)容大否?

MOV A,R1 ;偏大，取該點(diǎn)位置

DEC A ;減一

MOV R3,A ;作為新的區(qū)間高端

SJMP FD81 ;繼續(xù)查找

FD86: MOV A,R1 ;偏小，取該點(diǎn)位置

INC A ;加一

MOV R2,A ;作為新的區(qū)間低端

SJMP FD81 ;繼續(xù)查找

FD89: MOV DPH,R6 ;相同，恢復(fù)首址

MOV DPL,R7

SETB OV ;查找失敗

RET

(30) 標(biāo)號： DDM1 功能：求單字節(jié)十六進(jìn)制無符號數(shù)據(jù)塊的平均值

入口條件：數(shù)據(jù)塊的首址在DPTR中，數(shù)據(jù)個數(shù)在R7中。

出口信息：平均值在累加器A中。

影響資源：PSW、A、R2～R6 堆棧需求： 4字節(jié)

DDM1: MOV A,R7 ;保存數(shù)據(jù)個數(shù)

MOV R2,A

PUSH DPH

PUSH DPL

CLR A ;初始化累加和

MOV R4,A

MOV R5,A

DM11: MOVX A,@DPTR ;讀取一個數(shù)據(jù)

ADD A,R5 ;累加到累加和中

MOV R5,A

JNC DM12

INC R4

DM12: INC DPTR ;調(diào)整指針

DJNZ R2,DM11 ;累加完全部數(shù)據(jù)

LCALL D457 ;求平均值(R4R5/R7-→R3)

MOV A,R3 ;取平均值

POP DPL

POP DPH

RET

(31) 標(biāo)號： DDM2 功能：求雙字節(jié)十六進(jìn)制無符號數(shù)據(jù)塊的平均值

入口條件：數(shù)據(jù)塊的首址在DPTR中，雙字節(jié)數(shù)據(jù)總個數(shù)在R7中。

出口信息：平均值在R4、R5中。

影響資源：PSW、A、R2～R6 堆棧需求： 4字節(jié)

DDM2: MOV A,R7 ;保存數(shù)據(jù)個數(shù)

MOV R2,A ;初始化數(shù)據(jù)指針

PUSH DPL ;保持首址

PUSH DPH

CLR A ;初始化累加和

MOV R3,A

MOV R4,A

MOV R5,A

DM20: MOVX A,@DPTR ;讀取一個數(shù)據(jù)的高字節(jié)

MOV B,A

INC DPTR

MOVX A,@DPTR ;讀取一個數(shù)據(jù)的低字節(jié)

INC DPTR

ADD A,R5 ;累加到累加和中

MOV R5,A

MOV A,B

ADDC A,R4

MOV R4,A

JNC DM21

INC R3

DM21: DJNZ R2,DM20 ;累加完全部數(shù)據(jù)

POP DPH ;恢復(fù)首址

POP DPL

LJMP DV31 ;求R3R4R5/R7-→R4R5，得到平均值

(32) 標(biāo)號： XR1 功能：求單字節(jié)數(shù)據(jù)塊的(異或)校驗(yàn)和

入口條件：數(shù)據(jù)塊的首址在DPTR中，數(shù)據(jù)的個數(shù)在R6、R7中。

出口信息：校驗(yàn)和在累加器A中。

影響資源：PSW、A、B、R4～R7 堆棧需求： 2字節(jié)

XR1: MOV R4,DPH ;保存數(shù)據(jù)塊的首址

MOV R5,DPL

MOV A,R7 ;雙字節(jié)計數(shù)器調(diào)整

JZ XR10

INC R6

XR10: MOV B,#0 ;校驗(yàn)和初始化

XR11: MOVX A,@DPTR ;讀取一個數(shù)據(jù)

XRL B,A ;異或運(yùn)算

INC DPTR ;指向下一個數(shù)據(jù)

DJNZ R7,XR11 ;雙字節(jié)計數(shù)器減一

DJNZ R6,XR11

MOV DPH,R4 ;恢復(fù)數(shù)據(jù)首址

MOV DPL,R5

MOV A,B ;取校驗(yàn)和

RET

(33) 標(biāo)號： XR2 功能：求雙字節(jié)數(shù)據(jù)塊的(異或)校驗(yàn)和

入口條件：數(shù)據(jù)塊的首址在DPTR中，雙字節(jié)數(shù)據(jù)總個數(shù)在R6、R7中。

出口信息：校驗(yàn)和在R2、R3中。

影響資源：PSW、A、R2～R7 堆棧需求： 2字節(jié)

XR2: MOV R4,DPH ;保存數(shù)據(jù)塊的首址

MOV R5,DPL

MOV A,R7 ;雙字節(jié)計數(shù)器調(diào)整

JZ XR20

INC R6

XR20: CLR A ;校驗(yàn)和初始化

MOV R2,A

MOV R3,A

XR21: MOVX A,@DPTR ;讀取一個數(shù)據(jù)的高字節(jié)

XRL A,R2 ;異或運(yùn)算

MOV R2,A

INC DPTR

MOVX A,@DPTR ;讀取一個數(shù)據(jù)的低字節(jié)

XRL A,R3 ;異或運(yùn)算

MOV R3,A

INC DPTR ;指向下一個數(shù)據(jù)

DJNZ R7,XR21 ;雙字節(jié)計數(shù)器減一

DJNZ R6,XR21

MOV DPH,R4 ;恢復(fù)數(shù)據(jù)首址

MOV DPL,R5

RET

(34) 標(biāo)號： SORT 功能：單字節(jié)無符號數(shù)據(jù)塊排序(增序)[!--empirenews.page--]

入口條件：數(shù)據(jù)塊的首址在R0中，字節(jié)數(shù)在R7中。

出口信息：完成排序(增序)

影響資源：PSW、A、R2～R6 堆棧需求： 2字節(jié)

SORT: MOV A,R7

MOV R5,A ;比較次數(shù)初始化

SRT1: CLR F0 ;交換標(biāo)志初始化

MOV A,R5 ;取上遍比較次數(shù)

DEC A ;本遍比上遍減少一次

MOV R5,A ;保存本遍次數(shù)

MOV R2,A ;復(fù)制到計數(shù)器中

JZ SRT5 ;若為零，排序結(jié)束

MOV A,R0 ;保存數(shù)據(jù)指針

MOV R6,A

SRT2: MOV A,@R0 ;讀取一個數(shù)據(jù)

MOV R3,A

INC R0 ;指向下一個數(shù)據(jù)

MOV A,@R0 ;再讀取一個數(shù)據(jù)

MOV R4,A

CLR C

SUBB A,R3 ;比較兩個數(shù)據(jù)的大小

JNC SRT4 ;順序正確(增序或相同)，不必交換

SETB F0 ;設(shè)立交換標(biāo)志

MOV A,R3 ;將兩個數(shù)據(jù)交換位置

MOV @R0,A

DEC R0

MOV A,R4

MOV @R0,A

INC R0 ;指向下一個數(shù)據(jù)

SRT4: DJNZ R2,SRT2 ;完成本遍的比較次數(shù)

MOV A,R6 ;恢復(fù)數(shù)據(jù)首址

MOV R0,A

JB F0,SRT1 ;本遍若進(jìn)行過交換，則需繼續(xù)排序

SRT5: RET ;排序結(jié)束

END

(二) MCS-51 浮點(diǎn)運(yùn)算子程序庫及其使用說明

本浮點(diǎn)子程序庫有三個不同層次的版本，以便適應(yīng)不同的應(yīng)用場合：

1.小型庫(FQ51A.ASM)：只包含浮點(diǎn)加、減、乘、除子程序。

2.中型庫(FQ51B.ASM)：在小型庫的基礎(chǔ)上再增加絕對值、倒數(shù)、比較、平方、開平方、

數(shù)制轉(zhuǎn)換等子程序。

3.大型庫(FQ51.ASM)：包含本說明書中的全部子程序。

為便于讀者使用本程序庫，先將有關(guān)約定說明如下：

1.雙字節(jié)定點(diǎn)操作數(shù)：用[R0]或[R1]來表示存放在由R0或R1指示的連續(xù)單元中的數(shù)

據(jù)，地址小的單元存放高字節(jié)。如果[R0]=1234H，若(R0)=30H，則(30H)=12H，(31H)=34H。

2.二進(jìn)制浮點(diǎn)操作數(shù)：用三個字節(jié)表示，第一個字節(jié)的最高位為數(shù)符，其余七位為

階碼(補(bǔ)碼形式)，第二字節(jié)為尾數(shù)的高字節(jié)，第三字節(jié)為尾數(shù)的低字節(jié)，尾數(shù)用雙字節(jié)

純小數(shù)(原碼)來表示。當(dāng)尾數(shù)的最高位為1時，便稱為規(guī)格化浮點(diǎn)數(shù)，簡稱操作數(shù)。在

程序說明中，也用[R0]或[R1]來表示R0或R1指示的浮點(diǎn)操作數(shù)，例如：當(dāng)[R0]=-6.000時，

則二進(jìn)制浮點(diǎn)數(shù)表示為83C000H。若(R0)=30H，則(30H)=83H,(31H)=0C0H,(32H)=00H。

3.十進(jìn)制浮點(diǎn)操作數(shù)：用三個字節(jié)表示，第一個字節(jié)的最高位為數(shù)符，其余七位為

階碼(二進(jìn)制補(bǔ)碼形式)，第二字節(jié)為尾數(shù)的高字節(jié)，第三字節(jié)為尾數(shù)的低字節(jié)，尾數(shù)用

雙字節(jié)BCD碼純小數(shù)(原碼)來表示。當(dāng)十進(jìn)制數(shù)的絕對值大于1時，階碼就等于整數(shù)

部分的位數(shù)，如 876.5 的階碼是03H，-876.5 的階碼是 83H;當(dāng)十進(jìn)制數(shù)的絕對值小于1

時，階碼就等于 80H 減去小數(shù)點(diǎn)后面零的個數(shù)，例如 0.00382 的階碼是 7EH，-0.00382

的階碼是 0FEH。在程序說明中，用[R0]或[R1]來表示R0或R1指示的十進(jìn)制浮點(diǎn)操作數(shù)。例

如有一個十進(jìn)制浮點(diǎn)操作數(shù)存放在30H、31H、32H中，數(shù)值是 -0.07315，即-0.7315乘以10

的-1次方，則(30H)=0FFH，31H=73H，(32H)=15H。若用[R0]來指向它，則應(yīng)使(R0)=30H。

4.運(yùn)算精度：單次定點(diǎn)運(yùn)算精度為結(jié)果最低位的當(dāng)量值;單次二進(jìn)制浮點(diǎn)算術(shù)運(yùn)算

的精度優(yōu)于十萬分之三;單次二進(jìn)制浮點(diǎn)超越函數(shù)運(yùn)算的精度優(yōu)于萬分之一;BCD碼浮

點(diǎn)數(shù)本身的精度比較低(萬分之一到千分之一)，不宜作為運(yùn)算的操作數(shù)，僅用于輸入或

輸出時的數(shù)制轉(zhuǎn)換。不管那種數(shù)據(jù)格式，隨著連續(xù)運(yùn)算的次數(shù)增加，精度都會下降。

5.工作區(qū)：數(shù)據(jù)工作區(qū)固定在A、B、R2～R7，數(shù)符或標(biāo)志工作區(qū)固定在PSW和23H單

元(位1CH～1FH)。在浮點(diǎn)系統(tǒng)中，R2、R3、R4和位1FH為第一工作區(qū)，R5、R6、R7和位1EH

為第二工作區(qū)。用戶只要不在工作區(qū)中存放無關(guān)的或非消耗性的信息，程序就具有較好的

透明性。

6.子程序調(diào)用范例：由于本程序庫特別注意了各子程序接口的相容性，很容易采用

積木方式(或流水線方式)完成一個公式的計算。以浮點(diǎn)運(yùn)算為例：

計算 y = Ln √ | Sin (ab/c+d) |

已知：a=-123.4;b=0.7577;c=56.34;d=1.276; 它們分別存放在30H、33H、36H、

39H開始的連續(xù)三個單元中。用BCD碼浮點(diǎn)數(shù)表示時，分別為a=831234H;b=007577H;

c=025634H;d=011276H。

求解過程：通過調(diào)用BTOF子程序，將各變量轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)，再進(jìn)行各

種運(yùn)算，最后調(diào)用FTOB子程序，還原成十進(jìn)制形式，供輸出使用。程序如下：

TEST: MOV R0,#39H ;指向BCD碼浮點(diǎn)操作數(shù)d

LCALL BTOF ;將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)

MOV R0,#36H ;指向BCD碼浮點(diǎn)操作數(shù)c

LCALL BTOF ;將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)

MOV R0,#33H ;指向BCD碼浮點(diǎn)操作數(shù)b

LCALL BTOF ;將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)

MOV R0,#30H ;指向BCD碼浮點(diǎn)操作數(shù)a

LCALL BTOF ;將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)

MOV R1,#33H ;指向二進(jìn)制浮點(diǎn)操作數(shù)b

LCALL FMUL ;進(jìn)行浮點(diǎn)乘法運(yùn)算

MOV R1,#36H ;指向二進(jìn)制浮點(diǎn)操作數(shù)c

LCALL FDIV ;進(jìn)行浮點(diǎn)除法運(yùn)算

MOV R1,#39H ;指向二進(jìn)制浮點(diǎn)操作數(shù)d

LCALL FADD ;進(jìn)行浮點(diǎn)加法運(yùn)算

LCALL FSIN ;進(jìn)行浮點(diǎn)正弦運(yùn)算

LCALL FABS ;進(jìn)行浮點(diǎn)絕對值運(yùn)算

LCALL FSQR ;進(jìn)行浮點(diǎn)開平方運(yùn)算

LCALL FLN ;進(jìn)行浮點(diǎn)對數(shù)運(yùn)算

LCALL FTOB ;將結(jié)果轉(zhuǎn)換成BCD碼浮點(diǎn)數(shù)

STOP: LJMP STOP

END

運(yùn)行結(jié)果，[R0]=804915H，即y=-0.4915，比較精確的結(jié)果應(yīng)該是-0.491437。

(1) 標(biāo)號： FSDT 功能：浮點(diǎn)數(shù)格式化

入口條件：待格式化浮點(diǎn)操作數(shù)在[R0]中。

出口信息：已格式化浮點(diǎn)操作數(shù)仍在[R0]中。

影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： 6字節(jié)

FSDT: LCALL MVR0 ;將待格式化操作數(shù)傳送到第一工作區(qū)中[!--empirenews.page--]

LCALL RLN ;通過左規(guī)完成格式化

LJMP MOV0 ;將已格式化浮點(diǎn)操作數(shù)傳回到[R0]中

(2) 標(biāo)號： FADD 功能：浮點(diǎn)數(shù)加法

入口條件：被加數(shù)在[R0]中，加數(shù)在[R1]中。

出口信息：OV=0時，和仍在[R0]中，OV=1時，溢出。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 6字節(jié)

FADD: CLR F0 ;設(shè)立加法標(biāo)志

SJMP AS ;計算代數(shù)和

(3) 標(biāo)號： FSUB 功能：浮點(diǎn)數(shù)減法

入口條件：被減數(shù)在[R0]中，減數(shù)在[R1]中。

出口信息：OV=0時，差仍在[R0]中，OV=1時，溢出。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

FSUB: SETB F0 ;設(shè)立減法標(biāo)志

AS: LCALL MVR1 ;計算代數(shù)和。先將[R1]傳送到第二工作區(qū)

MOV C,F0 ;用加減標(biāo)志來校正第二操作數(shù)的有效符號

RRC A

XRL A,@R1

MOV C,ACC.7

ASN: MOV 1EH,C ;將第二操作數(shù)的有效符號存入位1EH中

XRL A,@R0 ;與第一操作數(shù)的符號比較

RLC A

MOV F0,C ;保存比較結(jié)果

LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中

LCALL AS1 ;在工作寄存器中完成代數(shù)運(yùn)算

MOV0: INC R0 ;將結(jié)果傳回到[R0]中的子程序入口

INC R0

MOV A,R4 ;傳回尾數(shù)的低字節(jié)

MOV @R0,A

DEC R0

MOV A,R3 ;傳回尾數(shù)的高字節(jié)

MOV @R0,A

DEC R0

MOV A,R2 ;取結(jié)果的階碼

MOV C,1FH ;取結(jié)果的數(shù)符

MOV ACC.7,C ;拼入階碼中

MOV @R0,A

CLR ACC.7 ;不考慮數(shù)符

CLR OV ;清除溢出標(biāo)志

CJNE A,#3FH,MV01;階碼是否上溢?

SETB OV ;設(shè)立溢出標(biāo)志

MV01: MOV A,@R0 ;取出帶數(shù)符的階碼

RET

MVR0: MOV A,@R0 ;將[R0]傳送到第一工作區(qū)中的子程序

MOV C,ACC.7 ;將數(shù)符保存在位1FH中

MOV 1FH,C

MOV C,ACC.6 ;將階碼擴(kuò)充為8bit補(bǔ)碼

MOV ACC.7,C

MOV R2,A ;存放在R2中

INC R0

MOV A,@R0 ;將尾數(shù)高字節(jié)存放在R3中

MOV R3,A

INC R0

MOV A,@R0 ;將尾數(shù)低字節(jié)存放在R4中

MOV R4,A

DEC R0 ;恢復(fù)數(shù)據(jù)指針

DEC R0

RET

MVR1: MOV A,@R1 ;將[R1]傳送到第二工作區(qū)中的子程序

MOV C,ACC.7 ;將數(shù)符保存在位1EH中

MOV 1EH,C

MOV C,ACC.6 ;將階碼擴(kuò)充為8bit補(bǔ)碼

MOV ACC.7,C

MOV R5,A ;存放在R5中

INC R1

MOV A,@R1 ;將尾數(shù)高字節(jié)存放在R6中

MOV R6,A

INC R1

MOV A,@R1 ;將尾數(shù)低字節(jié)存放在R7中

MOV R7,A

DEC R1 ;恢復(fù)數(shù)據(jù)指針

DEC R1

RET

AS1: MOV A,R6 ;讀取第二操作數(shù)尾數(shù)高字節(jié)

ORL A,R7

JZ AS2 ;第二操作數(shù)為零，不必運(yùn)算

MOV A,R3 ;讀取第一操作數(shù)尾數(shù)高字節(jié)

ORL A,R4

JNZ EQ1

MOV A,R6 ;第一操作數(shù)為零，結(jié)果以第二操作數(shù)為準(zhǔn)

MOV R3,A

MOV A,R7

MOV R4,A

MOV A,R5

MOV R2,A

MOV C,1EH

MOV 1FH,C

AS2: RET

EQ1: MOV A,R2 ;對階，比較兩個操作數(shù)的階碼

XRL A,R5

JZ AS4 ;階碼相同，對階結(jié)束

JB ACC.7,EQ3;階符互異

MOV A,R2 ;階符相同，比較大小

CLR C

SUBB A,R5

JC EQ4

EQ2: CLR C ;第二操作數(shù)右規(guī)一次

MOV A,R6 ;尾數(shù)縮小一半

RRC A

MOV R6,A

MOV A,R7

RRC A

MOV R7,A

INC R5 ;階碼加一

ORL A,R6 ;尾數(shù)為零否?

JNZ EQ1 ;尾數(shù)不為零，繼續(xù)對階

MOV A,R2 ;尾數(shù)為零，提前結(jié)束對階

MOV R5,A

SJMP AS4

EQ3: MOV A,R2 ;判斷第一操作數(shù)階符

JNB ACC.7,EQ2;如為正，右規(guī)第二操作數(shù)

EQ4: CLR C

LCALL RR1 ;第一操作數(shù)右規(guī)一次

ORL A,R3 ;尾數(shù)為零否?

JNZ EQ1 ;不為零，繼續(xù)對階

MOV A,R5 ;尾數(shù)為零，提前結(jié)束對階

MOV R2,A

AS4: JB F0,AS5 ;尾數(shù)加減判斷

MOV A,R4 ;尾數(shù)相加

ADD A,R7

MOV R4,A

MOV A,R3

ADDC A,R6

MOV R3,A

JNC AS2

LJMP RR1 ;有進(jìn)位，右規(guī)一次

AS5: CLR C ;比較絕對值大小

MOV A,R4

SUBB A,R7

MOV B,A

MOV A,R3

SUBB A,R6

JC AS6

MOV R4,B ;第一尾數(shù)減第二尾數(shù)

MOV R3,A

LJMP RLN ;結(jié)果規(guī)格化

AS6: CPL 1FH ;結(jié)果的符號與第一操作數(shù)相反

CLR C ;結(jié)果的絕對值為第二尾數(shù)減第一尾數(shù)

MOV A,R7

SUBB A,R4

MOV R4,A

MOV A,R6

SUBB A,R3

MOV R3,A

RLN: MOV A,R3 ;浮點(diǎn)數(shù)規(guī)格化

ORL A,R4 ;尾數(shù)為零否?

JNZ RLN1

MOV R2,#0C1H;階碼取最小值

RET

RLN1: MOV A,R3

JB ACC.7,RLN2;尾數(shù)最高位為一否?

CLR C ;不為一，左規(guī)一次

LCALL RL1

SJMP RLN ;繼續(xù)判斷

RLN2: CLR OV ;規(guī)格化結(jié)束

RET

RL1: MOV A,R4 ;第一操作數(shù)左規(guī)一次

RLC A ;尾數(shù)擴(kuò)大一倍

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

DEC R2 ;階碼減一

CJNE R2,#0C0H,RL1E;階碼下溢否?

CLR A

MOV R3,A ;階碼下溢，操作數(shù)以零計

MOV R4,A

MOV R2,#0C1H

RL1E: CLR OV

RET

RR1: MOV A,R3 ;第一操作數(shù)右規(guī)一次

RRC A ;尾數(shù)縮小一半

MOV R3,A

MOV A,R4

RRC A

MOV R4,A

INC R2 ;階碼加一

CLR OV ;清溢出標(biāo)志

CJNE R2,#40H,RR1E;階碼上溢否?

MOV R2,#3FH ;階碼溢出[!--empirenews.page--]

SETB OV

RR1E: RET

(4) 標(biāo)號： FMUL 功能：浮點(diǎn)數(shù)乘法

入口條件：被乘數(shù)在[R0]中，乘數(shù)在[R1]中。

出口信息：OV=0時，積仍在[R0]中，OV=1時，溢出。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

FMUL: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中

MOV A,@R0

XRL A,@R1 ;比較兩個操作數(shù)的符號

RLC A

MOV 1FH,C ;保存積的符號

LCALL MUL0 ;計算積的絕對值

LJMP MOV0 ;將結(jié)果傳回到[R0]中

MUL0: LCALL MVR1 ;將[R1]傳送到第二工作區(qū)中

MUL1: MOV A,R3 ;第一尾數(shù)為零否?

ORL A,R4

JZ MUL6

MOV A,R6 ;第二尾數(shù)為零否?

ORL A,R7

JZ MUL5

MOV A,R7 ;計算R3R4×R6R7-→R3R4

MOV B,R4

MUL AB

MOV A,B

XCH A,R7

MOV B,R3

MUL AB

ADD A,R7

MOV R7,A

CLR A

ADDC A,B

XCH A,R4

MOV B,R6

MUL AB

ADD A,R7

MOV R7,A

MOV A,B

ADDC A,R4

MOV R4,A

CLR A

RLC A

XCH A,R3

MOV B,R6

MUL AB

ADD A,R4

MOV R4,A

MOV A,B

ADDC A,R3

MOV R3,A

JB ACC.7,MUL2;積為規(guī)格化數(shù)否?

MOV A,R7 ;左規(guī)一次

RLC A

MOV R7,A

LCALL RL1

MUL2: MOV A,R7

JNB ACC.7,MUL3

INC R4

MOV A,R4

JNZ MUL3

INC R3

MOV A,R3

JNZ MUL3

MOV R3,#80H

INC R2

MUL3: MOV A,R2 ;求積的階碼

ADD A,R5

MD: MOV R2,A ;階碼溢出判斷

JB ACC.7,MUL4

JNB ACC.6,MUL6

MOV R2,#3FH ;階碼上溢，設(shè)立標(biāo)志

SETB OV

RET

MUL4: JB ACC.6,MUL6

MUL5: CLR A ;結(jié)果清零(因子為零或階碼下溢)

MOV R3,A

MOV R4,A

MOV R2,#41H

MUL6: CLR OV

RET

(5) 標(biāo)號： FDIV 功能：浮點(diǎn)數(shù)除法

入口條件：被除數(shù)在[R0]中，除數(shù)在[R1]中。

出口信息：OV=0時，商仍在[R0]中，OV=1時，溢出。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 5字節(jié)

FDIV: INC R0

MOV A,@R0

INC R0

ORL A,@R0

DEC R0

DEC R0

JNZ DIV1

MOV @R0,#41H;被除數(shù)為零，不必運(yùn)算

CLR OV

RET

DIV1: INC R1

MOV A,@R1

INC R1

ORL A,@R1

DEC R1

DEC R1

JNZ DIV2

SETB OV ;除數(shù)為零，溢出

RET

DIV2: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中

MOV A,@R0

XRL A,@R1 ;比較兩個操作數(shù)的符號

RLC A

MOV 1FH,C ;保存結(jié)果的符號

LCALL MVR1 ;將[R1]傳送到第二工作區(qū)中

LCALL DIV3 ;調(diào)用工作區(qū)浮點(diǎn)除法

LJMP MOV0 ;回傳結(jié)果

DIV3: CLR C ;比較尾數(shù)的大小

MOV A,R4

SUBB A,R7

MOV A,R3

SUBB A,R6

JC DIV4

LCALL RR1 ;被除數(shù)右規(guī)一次

SJMP DIV3

DIV4: CLR A ;借用R0R1R2作工作寄存器

XCH A,R0 ;清零并保護(hù)之

PUSH ACC

CLR A

XCH A,R1

PUSH ACC

MOV A,R2

PUSH ACC

MOV B,#10H ;除法運(yùn)算，R3R4/R6R7-→R0R1

DIV5: CLR C

MOV A,R1

RLC A

MOV R1,A

MOV A,R0

RLC A

MOV R0,A

MOV A,R4

RLC A

MOV R4,A

XCH A,R3

RLC A

XCH A,R3

MOV F0,C

CLR C

SUBB A,R7

MOV R2,A

MOV A,R3

SUBB A,R6

ANL C,/F0

JC DIV6

MOV R3,A

MOV A,R2

MOV R4,A

INC R1

DIV6: DJNZ B,DIV5

MOV A,R6 ;四舍五入

CLR C

RRC A

SUBB A,R3

CLR A

ADDC A,R1 ;將結(jié)果存回R3R4

MOV R4,A

CLR A

ADDC A,R0

MOV R3,A

POP ACC ;恢復(fù)R0R1R2

MOV R2,A

POP ACC

MOV R1,A

POP ACC

MOV R0,A

MOV A,R2 ;計算商的階碼

CLR C

SUBB A,R5

LCALL MD ;階碼檢驗(yàn)

LJMP RLN ;規(guī)格化

(6) 標(biāo)號： FCLR 功能：浮點(diǎn)數(shù)清零

入口條件：操作數(shù)在[R0]中。

出口信息：操作數(shù)被清零。

影響資源：A 堆棧需求： 2字節(jié)

FCLR: INC R0

INC R0

CLR A

MOV @R0,A

DEC R0

MOV @R0,A

DEC R0

MOV @R0,#41H

RET

(7) 標(biāo)號： FZER 功能：浮點(diǎn)數(shù)判零

入口條件：操作數(shù)在[R0]中。

出口信息：若累加器A為零，則操作數(shù)[R0]為零，否則不為零。

影響資源：A 堆棧需求： 2字節(jié)

FZER: INC R0

INC R0

MOV A,@R0

DEC R0

ORL A,@R0

DEC R0

JNZ ZERO

MOV @R0,#41H

ZERO: RET

(8) 標(biāo)號： FMOV 功能：浮點(diǎn)數(shù)傳送

入口條件：源操作數(shù)在[R1]中，目標(biāo)地址為[R0]。

出口信息：[R0]=[R1]，[R1]不變。

影響資源：A 堆棧需求： 2字節(jié)

FMOV: INC R0

INC R0

INC R1

INC R1

MOV A,@R1

MOV @R0,A

DEC R0

DEC R1

MOV A,@R1

MOV @R0,A

DEC R0

DEC R1

MOV A,@R1

MOV @R0,A

RET

(9) 標(biāo)號： FPUS 功能：浮點(diǎn)數(shù)壓棧

[!--empirenews.page--]

入口條件：操作數(shù)在[R0]中。

出口信息：操作數(shù)壓入棧頂。

影響資源：A、R2、R3 堆棧需求： 5字節(jié)

FPUS: POP ACC ;將返回地址保存在R2R3中

MOV R2,A

POP ACC

MOV R3,A

MOV A,@R0 ;將操作數(shù)壓入堆棧

PUSH ACC

INC R0

MOV A,@R0

PUSH ACC

INC R0

MOV A,@R0

PUSH ACC

DEC R0

DEC R0

MOV A,R3 ;將返回地址壓入堆棧

PUSH ACC

MOV A,R2

PUSH ACC

RET ;返回主程序

(10) 標(biāo)號： FPOP 功能：浮點(diǎn)數(shù)出棧

入口條件：操作數(shù)處于棧頂。

出口信息：操作數(shù)彈至[R0]中。

影響資源：A、R2、R3 堆棧需求： 2字節(jié)

FPOP: POP ACC ;將返回地址保存在R2R3中

MOV R2,A

POP ACC

MOV R3,A

INC R0

INC R0

POP ACC ;將操作數(shù)彈出堆棧，傳送到[R0]中

MOV @R0,A

DEC R0

POP ACC

MOV @R0,A

DEC R0

POP ACC

MOV @R0,A

MOV A,R3 ;將返回地址壓入堆棧

PUSH ACC

MOV A,R2

PUSH ACC

RET ;返回主程序

(11) 標(biāo)號： FCMP 功能：浮點(diǎn)數(shù)代數(shù)值比較(不影響待比較操作數(shù))

入口條件：待比較操作數(shù)分別在[R0]和[R1]中。

出口信息：若CY=1，則[R0] < [R1]，若CY=0且A=0則 [R0] = [R1]，否則[R0] > [R1]。

影響資源：A、B、PSW 堆棧需求： 2字節(jié)

FCMP: MOV A,@R0 ;數(shù)符比較

XRL A,@R1

JNB ACC.7,CMP2

MOV A,@R0 ;兩數(shù)異號，以[R0]數(shù)符為準(zhǔn)

RLC A

MOV A,#0FFH

RET

CMP2: MOV A,@R1 ;兩數(shù)同號，準(zhǔn)備比較階碼

MOV C,ACC.6

MOV ACC.7,C

MOV B,A

MOV A,@R0

MOV C,ACC.7

MOV F0,C ;保存[R0]的數(shù)符

MOV C,ACC.6

MOV ACC.7,C

CLR C ;比較階碼

SUBB A,B

JZ CMP6

RLC A ;取階碼之差的符號

JNB F0,CMP5

CPL C ;[R0]為負(fù)時，結(jié)果取反

CMP5: MOV A,#0FFH ;兩數(shù)不相等

RET

CMP6: INC R0 ;階碼相同時，準(zhǔn)備比較尾數(shù)

INC R0

INC R1

INC R1

CLR C

MOV A,@R0

SUBB A,@R1

MOV B,A ;保存部分差

DEC R0

DEC R1

MOV A,@R0

SUBB A,@R1

DEC R0

DEC R1

ORL A,B ;生成是否相等信息

JZ CMP7

JNB F0,CMP7

CPL C ;[R0]為負(fù)時，結(jié)果取反

CMP7: RET

(12) 標(biāo)號： FABS 功能：浮點(diǎn)絕對值函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中。

影響資源：A 堆棧需求： 2字節(jié)

FABS: MOV A,@R0 ;讀取操作數(shù)的階碼

CLR ACC.7 ;清除數(shù)符

MOV @R0,A ;回傳階碼

RET

(13) 標(biāo)號： FSGN 功能：浮點(diǎn)符號函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：累加器 A=1 時為正數(shù)，A=0FFH時為負(fù)數(shù)，A=0 時為零。

影響資源：PSW、A 堆棧需求： 2字節(jié)

FSGN: INC R0 ;讀尾數(shù)

MOV A,@R0

INC R0

ORL A,@R0

DEC R0

DEC R0

JNZ SGN

RET ;尾數(shù)為零，結(jié)束

SGN: MOV A,@R0 ;讀取操作數(shù)的階碼

RLC A ;取數(shù)符

MOV A,#1 ;按正數(shù)初始化

JNC SGN1 ;是正數(shù)，結(jié)束

MOV A,#0FFH ;是負(fù)數(shù)，改變標(biāo)志

SGN1: RET

(14) 標(biāo)號： FINT 功能：浮點(diǎn)取整函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中。

影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： 6字節(jié)

FINT: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中

LCALL INT ;在工作寄存器中完成取整運(yùn)算

LJMP MOV0 ;將結(jié)果傳回到[R0]中

INT: MOV A,R3

ORL A,R4

JNZ INTA

CLR 1FH ;尾數(shù)為零，階碼也清零，結(jié)束取整

MOV R2,#41H

RET

INTA: MOV A,R2

JZ INTB ;階碼為零否?

JB ACC.7,INTB;階符為負(fù)否?

CLR C

SUBB A,#10H ;階碼小于16否?

JC INTD

RET ;階碼大于16，已經(jīng)是整數(shù)

INTB: CLR A ;絕對值小于一，取整后正數(shù)為零，負(fù)數(shù)為負(fù)一

MOV R4,A

MOV C,1FH

RRC A

MOV R3,A

RL A

MOV R2,A

JNZ INTC

MOV R2,#41H

INTC: RET

INTD: CLR F0 ;舍尾標(biāo)志初始化

INTE: CLR C

LCALL RR1 ;右規(guī)一次

ORL C,F0 ;記憶舍尾情況

MOV F0,C

CJNE R2,#10H,INTE;階碼達(dá)到16(尾數(shù)完全為整數(shù))否?

JNB F0,INTF ;舍去部分為零否?

JNB 1FH,INTF;操作數(shù)為正數(shù)否?

INC R4 ;對于帶小數(shù)的負(fù)數(shù)，向下取整

MOV A,R4

JNZ INTF

INC R3

INTF: LJMP RLN ;將結(jié)果規(guī)格化

(15) 標(biāo)號： FRCP 功能：浮點(diǎn)倒數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 5字節(jié)

FRCP: MOV A,@R0

MOV C,ACC.7

MOV 1FH,C ;保存數(shù)符

MOV C,ACC.6 ;絕對值傳送到第二工作區(qū)

MOV ACC.7,C

MOV R5,A

INC R0

MOV A,@R0

MOV R6,A

INC R0

MOV A,@R0

MOV R7,A

DEC R0

DEC R0

ORL A,R6

JNZ RCP

SETB OV ;零不能求倒數(shù)，設(shè)立溢出標(biāo)志

RET

RCP: MOV A,R6

JB ACC.7,RCP2;操作數(shù)格式化否?

CLR C ;格式化之

MOV A,R7

RLC A

[!--empirenews.page--]

MOV R7,A

MOV A,R6

RLC A

MOV R6,A

DEC R5

SJMP RCP

RCP2: MOV R2,#1 ;將數(shù)值1.00傳送到第一工作區(qū)

MOV R3,#80H

MOV R4,#0

LCALL DIV3 ;調(diào)用工作區(qū)浮點(diǎn)除法，求得倒數(shù)

LJMP MOV0 ;回傳結(jié)果

(16) 標(biāo)號： FSQU 功能：浮點(diǎn)數(shù)平方

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，平方值仍然在[R0]中，OV=1時溢出。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 9字節(jié)

FSQU: MOV A,R0 ;將操作數(shù)

XCH A,R1 ;同時作為乘數(shù)

PUSH ACC ;保存R1指針

LCALL FMUL ;進(jìn)行乘法運(yùn)算

POP ACC

MOV R1,A ;恢復(fù)R1指針

RET

(17) 標(biāo)號： FSQR 功能：浮點(diǎn)數(shù)開平方(快速逼近算法)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，平方根仍在[R0]中，OV=1時，負(fù)數(shù)開平方出錯。

影響資源：PSW、A、B、R2～R7 堆棧需求： 2字節(jié)

FSQR: MOV A,@R0

JNB ACC.7,SQR

SETB OV ;負(fù)數(shù)開平方，出錯

RET

SQR: INC R0

INC R0

MOV A,@R0

DEC R0

ORL A,@R0

DEC R0

JNZ SQ

MOV @R0,#41H;尾數(shù)為零，不必運(yùn)算

CLR OV

RET

SQ: MOV A,@R0

MOV C,ACC.6 ;將階碼擴(kuò)展成8bit補(bǔ)碼

MOV ACC.7,C

INC A ;加一

CLR C

RRC A ;除二

MOV @R0,A ;得到平方根的階碼，回存之

INC R0 ;指向被開方數(shù)尾數(shù)的高字節(jié)

JC SQR0 ;原被開方數(shù)的階碼是奇數(shù)嗎?

MOV A,@R0 ;是奇數(shù)，尾數(shù)右規(guī)一次

RRC A

MOV @R0,A

INC R0

MOV A,@R0

RRC A

MOV @R0,A

DEC R0

SQR0: MOV A,@R0

JZ SQR9 ;尾數(shù)為零，不必運(yùn)算

MOV R2,A ;將尾數(shù)傳送到R2R3中

INC R0

MOV A,@R0

MOV R3,A

MOV A,R2 ;快速開方，參閱定點(diǎn)子程序說明

ADD A,#57H

JC SQR2

ADD A,#45H

JC SQR1

ADD A,#24H

MOV B,#0E3H

MOV R4,#80H

SJMP SQR3

SQR1: MOV B,#0B2H

MOV R4,#0A0H

SJMP SQR3

SQR2: MOV B,#8DH

MOV R4,#0D0H

SQR3: MUL AB

MOV A,B

ADD A,R4

MOV R4,A

MOV B,A

MUL AB

XCH A,R3

CLR C

SUBB A,R3

MOV R3,A

MOV A,B

XCH A,R2

SUBB A,R2

MOV R2,A

SQR4: SETB C

MOV A,R4

RLC A

MOV R6,A

CLR A

RLC A

MOV R5,A

MOV A,R3

SUBB A,R6

MOV B,A

MOV A,R2

SUBB A,R5

JC SQR5

INC R4

MOV R2,A

MOV R3,B

SJMP SQR4

SQR5: MOV A,R4

XCH A,R2

RRC A

MOV F0,C

MOV A,R3

MOV R5,A

MOV R4,#8

SQR6: CLR C

MOV A,R3

RLC A

MOV R3,A

CLR C

MOV A,R5

SUBB A,R2

JB F0,SQR7

JC SQR8

SQR7: MOV R5,A

INC R3

SQR8: CLR C

MOV A,R5

RLC A

MOV R5,A

MOV F0,C

DJNZ R4,SQR6

MOV A,R3 ;將平方根的尾數(shù)回傳到[R0]中

MOV @R0,A

DEC R0

MOV A,R2

MOV @R0,A

SQR9: DEC R0 ;數(shù)據(jù)指針回歸原位

CLR OV ;開方結(jié)果有效

RET

(18) 標(biāo)號： FPLN 功能：浮點(diǎn)數(shù)多項(xiàng)式計算

入口條件：自變量在[R0]中，多項(xiàng)式系數(shù)在調(diào)用指令之后，以40H結(jié)束。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。

影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 4字節(jié)

FPLN: POP DPH ;取出多項(xiàng)式系數(shù)存放地址

POP DPL

XCH A,R0 ;R0、R1交換角色，自變量在[R1]中

XCH A,R1

XCH A,R0

CLR A ;清第一工作區(qū)

MOV R2,A

MOV R3,A

MOV R4,A

CLR 1FH

PLN1: CLR A ;讀取一個系數(shù)，并裝入第二工作區(qū)

MOVC A,@A+DPTR

MOV C,ACC.7

MOV 1EH,C

MOV C,ACC.6

MOV ACC.7,C

MOV R5,A

INC DPTR

CLR A

MOVC A,@A+DPTR

MOV R6,A

INC DPTR

CLR A

MOVC A,@A+DPTR

MOV R7,A

INC DPTR ;指向下一個系數(shù)

MOV C,1EH ;比較兩個數(shù)符

RRC A

XRL A,23H

RLC A

MOV F0,C ;保存比較結(jié)果

LCALL AS1 ;進(jìn)行代數(shù)加法運(yùn)算

CLR A ;讀取下一個系數(shù)的第一個字節(jié)

MOVC A,@A+DPTR

CJNE A,#40H,PLN2;是結(jié)束標(biāo)志嗎?

XCH A,R0 ;運(yùn)算結(jié)束，恢復(fù)R0、R1原來的角色

XCH A,R1

XCH A,R0

LCALL MOV0 ;將結(jié)果回傳到[R0]中

CLR A

INC DPTR

JMP @A+DPTR ;返回主程序

PLN2: MOV A,@R1 ;比較自變量和中間結(jié)果的符號

XRL A,23H

RLC A

MOV 1FH,C ;保存比較結(jié)果

LCALL MUL0 ;進(jìn)行乘法運(yùn)算

SJMP PLN1 ;繼續(xù)下一項(xiàng)運(yùn)算

(19) 標(biāo)號： FLOG 功能：以10為底的浮點(diǎn)對數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，負(fù)數(shù)或零求對數(shù)出錯。

影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：9字節(jié)

FLOG: LCALL FLN ;先以e為底求對數(shù)

JNB OV,LOG

RET ;如溢出則停止計算

LOG: MOV R5,#0FFH;系數(shù)0.43430(1/Ln10)

MOV R6,#0DEH

MOV R7,#5CH

LCALL MUL1 ;通過相乘來換底[!--empirenews.page--]

LJMP MOV0 ;傳回結(jié)果

(20) 標(biāo)號： FLN 功能：以e為底的浮點(diǎn)對數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，負(fù)數(shù)或零求對數(shù)出錯。

影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： 7字節(jié)

FLN: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)

JB 1FH,LNOV;負(fù)數(shù)或零求對數(shù)，出錯

MOV A,R3

ORL A,R4

JNZ LN0

LNOV: SETB OV

RET

LN0: CLR C

LCALL RL1 ;左規(guī)一次

CLR A

XCH A,R2 ;保存原階碼，清零工作區(qū)的階碼

PUSH ACC

LCALL RLN ;規(guī)格化

LCALL MOV0 ;回傳

LCALL FPLN ;用多項(xiàng)式計算尾數(shù)的對數(shù)

DB 7BH,0F4H,30H;0.029808

DB 0FEH,85H,13H;-0.12996

DB 7FH,91H,51H;0.28382

DB 0FFH,0FAH,0BAH;-0.4897

DB 0,0FFH,0CAH;0.99918

DB 70H,0C0H,0;1.1442×10-5

DB 40H ;結(jié)束

POP ACC ;取出原階碼

JNZ LN1

RET ;如為零，則結(jié)束

LN1: CLR 1EH ;清第二區(qū)數(shù)符

MOV C,ACC.7

MOV F0,C ;保存階符

JNC LN2

CPL A ;當(dāng)階碼為負(fù)時，求其絕對值

INC A

LN2: MOV R2,A ;階碼的絕對值乘以0.69315

MOV B,#72H

MUL AB

XCH A,R2

MOV R7,B

MOV B,#0B1H

MUL AB

ADD A,R7

MOV R7,A ;乘積的尾數(shù)在R6R7R2中

CLR A

ADDC A,B

MOV R6,A

MOV R5,#8 ;乘積的階碼初始化(整數(shù)部分為一字節(jié))

LN3: JB ACC.7,LN4;乘積格式化

MOV A,R2

RLC A

MOV R2,A

MOV A,R7

RLC A

MOV R7,A

MOV A,R6

RLC A

MOV R6,A

DEC R5

SJMP LN3

LN4: MOV C,F0 ;取出階符，作為乘積的數(shù)符

MOV ACC.7,C

LJMP ASN ;與尾數(shù)的對數(shù)合并，得原操作數(shù)的對數(shù)

(21) 標(biāo)號： FE10 功能：以10為底的浮點(diǎn)指數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。

影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

FE10: MOV R5,#2 ;加權(quán)系數(shù)為3.3219(Log210)

MOV R6,#0D4H

MOV R7,#9AH

SJMP EXP ;先進(jìn)行加權(quán)運(yùn)算，后以2為底統(tǒng)一求冪

(22) 標(biāo)號： FEXP 功能：以e為底的浮點(diǎn)指數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。

影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

FEXP: MOV R5,#1 ;加權(quán)系數(shù)為1.44272(Lng2e)

MOV R6,#0B8H

MOV R7,#0ABH

EXP: CLR 1EH ;加權(quán)系數(shù)為正數(shù)

LCALL MVR0 ;將[R0]傳送到第一工作區(qū)

LCALL MUL1 ;進(jìn)行加權(quán)運(yùn)算

SJMP E20 ;以2為底統(tǒng)一求冪

(23) 標(biāo)號： FE2 功能：以2為底的浮點(diǎn)指數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。

影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

FE2: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)

E20: MOV A,R3

ORL A,R4

JZ EXP1 ;尾數(shù)為零

MOV A,R2

JB ACC.7,EXP2;階符為負(fù)?

SETB C

SUBB A,#6 ;階碼大于6否?

JC EXP2

JB 1FH,EXP0;數(shù)符為負(fù)否?

MOV @R0,#3FH;正指數(shù)過大，冪溢出

INC R0

MOV @R0,#0FFH

INC R0

MOV @R0,#0FFH

DEC R0

DEC R0

SETB OV

RET

EXP0: MOV @R0,#41H;負(fù)指數(shù)過大，冪下溢，清零處理

CLR A

INC R0

MOV @R0,A

INC R0

MOV @R0,A

DEC R0

DEC R0

CLR OV

RET

EXP1: MOV @R0,#1 ;指數(shù)為零，冪為1.00

INC R0

MOV @R0,#80H

INC R0

MOV @R0,#0

DEC R0

DEC R0

CLR OV

RET

EXP2: MOV A,R2 ;將指數(shù)復(fù)制到第二工作區(qū)

MOV R5,A

MOV A,R3

MOV R6,A

MOV A,R4

MOV R7,A

MOV C,1FH

MOV 1EH,C

LCALL INT ;對第一區(qū)取整

MOV A,R3

JZ EXP4

EXP3: CLR C ;使尾數(shù)高字節(jié)R3對應(yīng)一個字節(jié)整數(shù)

RRC A

INC R2

CJNE R2,#8,EXP3

EXP4: MOV R3,A

JNB 1FH,EXP5

CPL A ;并用補(bǔ)碼表示

INC A

EXP5: PUSH ACC ;暫時保存之

LCALL RLN ;重新規(guī)格化

CPL 1FH

SETB F0

LCALL AS1 ;求指數(shù)的小數(shù)部分

LCALL MOV0 ;回傳指數(shù)的小數(shù)部分

LCALL FPLN ;通過多項(xiàng)式計算指數(shù)的小數(shù)部分的冪

DB 77H,0B1H,0C9H;1.3564×10-3

DB 7AH,0A1H,68H;9.8514×10-3

DB 7CH,0E3H,4FH;0.055495

DB 7EH,0F5H,0E7H;0.24014

DB 0,0B1H,72H;0.69315

DB 1,80H,0 ;1.00000

DB 40H ;結(jié)束

POP ACC ;取出指數(shù)的整數(shù)部分

ADD A,R2 ;按補(bǔ)碼加到冪的階碼上

MOV R2,A

CLR 1FH ;冪的符號為正

LJMP MOV0 ;將冪傳回[R0]中

(24)標(biāo)號： DTOF 功能：雙字節(jié)十六進(jìn)制定點(diǎn)數(shù)轉(zhuǎn)換成格式化浮點(diǎn)數(shù)

入口條件：雙字節(jié)定點(diǎn)數(shù)的絕對值在[R0]中，數(shù)符在位1FH中，整數(shù)部分的位數(shù)在A中。

出口信息：轉(zhuǎn)換成格式化浮點(diǎn)數(shù)在[R0]中(三字節(jié))。

影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： 6字節(jié)

DTOF: MOV R2,A ;按整數(shù)的位數(shù)初始化階碼

MOV A,@R0 ;將定點(diǎn)數(shù)作尾數(shù)

MOV R3,A

INC R0

MOV A,@R0

[!--empirenews.page--]

MOV R4,A

DEC R0

LCALL RLN ;進(jìn)行規(guī)格化

LJMP MOV0 ;傳送結(jié)果到[R0]中

(25) 標(biāo)號： FTOD 功能：格式化浮點(diǎn)數(shù)轉(zhuǎn)換成雙字節(jié)定點(diǎn)數(shù)

入口條件：格式化浮點(diǎn)操作數(shù)在[R0]中。

出口信息：OV=1時溢出，OV=0時轉(zhuǎn)換成功：定點(diǎn)數(shù)的絕對值在[R0]中(雙字節(jié))，數(shù)符

在位1FH中，F(xiàn)0=1 時為整數(shù)，CY=1時為一字節(jié)整數(shù)一字節(jié)小數(shù)，否則為純小數(shù)。

影響資源：PSW、A、B、R2、R3、R4、位1FH 堆棧需求： 6字節(jié)

FTOD: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)

MOV A,R2

JZ FTD4 ;階碼為零，純小數(shù)

JB ACC.7,FTD4;階碼為負(fù)，純小數(shù)

SETB C

SUBB A,#10H

JC FTD1

SETB OV ;階碼大于16，溢出

RET

FTD1: SETB C

MOV A,R2

SUBB A,#8 ;階碼大于8否?

JC FTD3

FTD2: MOV B,#10H ;階碼大于8，按雙字節(jié)整數(shù)轉(zhuǎn)換

LCALL FTD8

SETB F0 ;設(shè)立雙字節(jié)整數(shù)標(biāo)志

CLR C

CLR OV

RET

FTD3: MOV B,#8 ;按一字節(jié)整數(shù)一字節(jié)小數(shù)轉(zhuǎn)換

LCALL FTD8

SETB C ;設(shè)立一字節(jié)整數(shù)一字節(jié)小數(shù)標(biāo)志

CLR F0

CLR OV

RET

FTD4: MOV B,#0 ;按純小數(shù)轉(zhuǎn)換

LCALL FTD8

CLR OV ;設(shè)立純小數(shù)標(biāo)志

CLR F0

CLR C

RET

FTD8: MOV A,R2 ;按規(guī)定的整數(shù)位數(shù)進(jìn)行右規(guī)

CJNE A,B,FTD9

MOV A,R3 ;將雙字節(jié)結(jié)果傳送到[R0]中

MOV @R0,A

INC R0

MOV A,R4

MOV @R0,A

DEC R0

RET

FTD9: CLR C

LCALL RR1 ;右規(guī)一次

SJMP FTD8

(26) 標(biāo)號： BTOF 功能：浮點(diǎn)BCD碼轉(zhuǎn)換成格式化浮點(diǎn)數(shù)

入口條件：浮點(diǎn)BCD碼操作數(shù)在[R0]中。

出口信息：轉(zhuǎn)換成的格式化浮點(diǎn)數(shù)仍在[R0]中。

影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：6字節(jié)

BTOF: INC R0 ;判斷是否為零。

INC R0

MOV A,@R0

MOV R7,A

DEC R0

MOV A,@R0

MOV R6,A

DEC R0

ORL A,R7

JNZ BTF0

MOV @R0,#41H;為零，轉(zhuǎn)換結(jié)束。

RET

BTF0: MOV A,@R0

MOV C,ACC.7

MOV 1DH,C ;保存數(shù)符。

CLR 1FH ;以絕對值進(jìn)行轉(zhuǎn)換。

MOV C,ACC.6 ;擴(kuò)充階碼為八位。

MOV ACC.7,C

MOV @R0,A

JNC BTF1

ADD A,#19 ;是否小于1E-19?

JC BTF2

MOV @R0,#41H;小于1E-19時以0計。

INC R0

MOV @R0,#0

INC R0

MOV @R0,#0

DEC R0

DEC R0

RET

BTF1: SUBB A,#19

JC BTF2

MOV A,#3FH ;大于1E19時封頂。

MOV C,1DH

MOV ACC.7,C

MOV @R0,A

INC R0

MOV @R0,#0FFH

INC R0

MOV @R0,#0FFH

DEC R0

DEC R0

RET

BTF2: CLR A ;準(zhǔn)備將BCD碼尾數(shù)轉(zhuǎn)換成十六進(jìn)制浮點(diǎn)數(shù)。

MOV R4,A

MOV R3,A

MOV R2,#10H ;至少兩個字節(jié)。

BTF3: MOV A,R7

ADD A,R7

DA A

MOV R7,A

MOV A,R6

ADDC A,R6

DA A

MOV R6,A

MOV A,R4

RLC A

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

DEC R2

JNB ACC.7,BTF3;直到尾數(shù)規(guī)格化。

MOV A,R6 ;四舍五入。

ADD A,#0B0H

CLR A

ADDC A,R4

MOV R4,A

CLR A

ADDC A,R3

MOV R3,A

JNC BTF4

MOV R3,#80H

INC R2

BTF4: MOV DPTR,#BTFL;準(zhǔn)備查表得到十進(jìn)制階碼對應(yīng)的浮點(diǎn)數(shù)。

MOV A,@R0

ADD A,#19 ;計算表格偏移量。

MOV B,#3

MUL AB

ADD A,DPL

MOV DPL,A

JNC BTF5

INC DPH

BTF5: CLR A ;查表。

MOVC A,@A+DPTR

MOV C,ACC.6

MOV ACC.7,C

MOV R5,A

MOV A,#1

MOVC A,@A+DPTR

MOV R6,A

MOV A,#2

MOVC A,@A+DPTR

MOV R7,A

LCALL MUL1 ;將階碼對應(yīng)的浮點(diǎn)數(shù)和尾數(shù)對應(yīng)的浮點(diǎn)數(shù)相乘。

MOV C,1DH ;取出數(shù)符。

MOV 1FH,C

LJMP MOV0 ;傳送轉(zhuǎn)換結(jié)果。

(27) 標(biāo)號： FTOB 功能：格式化浮點(diǎn)數(shù)轉(zhuǎn)換成浮點(diǎn)BCD碼

入口條件：格式化浮點(diǎn)操作數(shù)在[R0]中。

出口信息：轉(zhuǎn)換成的浮點(diǎn)BCD碼仍在[R0]中。

影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：6字節(jié)

FTOB: INC R0

MOV A,@R0

INC R0

ORL A,@R0

DEC R0

DEC R0

JNZ FTB0

MOV @R0,#41H

RET

FTB0: MOV A,@R0

MOV C,ACC.7

MOV 1DH,C

CLR ACC.7

MOV @R0,A

LCALL MVR0

MOV DPTR,#BFL0;絕對值大于或等于1時的查表起點(diǎn)。

MOV B,#0 ;十的0次冪。

MOV A,R2

JNB ACC.7,FTB1

MOV DPTR,#BTFL;絕對值小于1E-6時的查表起點(diǎn)。

MOV B,#0EDH ;十的-19次冪。

ADD A,#16

JNC FTB1

MOV DPTR,#BFLN;絕對值大于或等于1E-6時的查表起點(diǎn)。

MOV B,#0FAH ;十的-6次冪。

FTB1: CLR A ;查表，找到一個比待轉(zhuǎn)換浮點(diǎn)數(shù)大的整數(shù)冪。

MOVC A,@A+DPTR

MOV C,ACC.6

MOV ACC.7,C

MOV R5,A

MOV A,#1

MOVC A,@A+DPTR

MOV R6,A

MOV A,#2

MOVC A,@A+DPTR

MOV R7,A

MOV A,R5 ;和待轉(zhuǎn)換浮點(diǎn)數(shù)比較。

CLR C

SUBB A,R2

JB ACC.7,FTB2;差為負(fù)數(shù)。

JNZ FTB3

MOV A,R6

CLR C

[!--empirenews.page--]

SUBB A,R3

JC FTB2

JNZ FTB3

MOV A,R7

CLR C

SUBB A,R4

JC FTB2

JNZ FTB3

MOV R5,B ;正好是表格中的數(shù)。

INC R5 ;冪加一。

MOV R6,#10H ;尾數(shù)為0·1000。

MOV R7,#0

SJMP FTB6 ;傳送轉(zhuǎn)換結(jié)果。

FTB2: INC DPTR ;準(zhǔn)備表格下一項(xiàng)。

INC DPTR

INC DPTR

INC B ;冪加一。

SJMP FTB1 ;

FTB3: PUSH B ;保存冪值。

LCALL DIV3 ;相除，得到一個二進(jìn)制浮點(diǎn)數(shù)的純小數(shù)。

FTB4: MOV A,R2 ;取階碼。

JZ FTB5 ;為零嗎?

CLR C

LCALL RR1 ;右規(guī)。

SJMP FTB4

FTB5: POP ACC ;取出冪值。

MOV R5,A ;作為十進(jìn)制浮點(diǎn)數(shù)的階碼。

LCALL HB2 ;轉(zhuǎn)換尾數(shù)的十分位和百分位。

MOV R6,A

LCALL HB2 ;轉(zhuǎn)換尾數(shù)的千分位和萬分位。

MOV R7,A

MOV A,R3 ;四舍五入。

RLC A

CLR A

ADDC A,R7

DA A

MOV R7,A

CLR A

ADDC A,R6

DA A

MOV R6,A

JNC FTB6

MOV R6,#10H

INC R5

FTB6: INC R0 ;存放轉(zhuǎn)換結(jié)果。

INC R0

MOV A,R7

MOV @R0,A

DEC R0

MOV A,R6

MOV @R0,A

DEC R0

MOV A,R5

MOV C,1DH ;取出數(shù)符。

MOV ACC.7,C

MOV @R0,A

RET

HB2: MOV A,R4 ;尾數(shù)擴(kuò)大100倍。

MOV B,#100

MUL AB

MOV R4,A

MOV A,B

XCH A,R3

MOV B,#100

MUL AB

ADD A,R3

MOV R3,A

JNC HB21

INC B

HB21: MOV A,B ;將整數(shù)部分轉(zhuǎn)換成BCD碼。

MOV B,#10

DIV AB

SWAP A

ORL A,B

RET

BTFL: DB 41H,0ECH,1EH ;1.0000E-19

DB 45H,93H,93H ;1.0000E-18

DB 48H,0B8H,78H ;1.0000E-17

DB 4BH,0E6H,96H ;1.0000E-16

DB 4FH,90H,1DH ;1.0000E-15

DB 52H,0B4H,25H ;1.0000E-14

DB 55H,0E1H,2EH ;1.0000E-13

DB 59H,8CH,0BDH ;1.0000E-12

DB 5CH,0AFH,0ECH ;1.0000E-11

DB 5FH,0DBH,0E7H ;1.0000E-10

DB 63H,89H,70H ;1.0000E-9

DB 66H,0ABH,0CCH ;1.0000E-8

DB 69H,0D6H,0C0H ;1.0000E-7

BFLN: DB 6DH,86H,38H ;1.0000E-6

DB 70H,0A7H,0C6H ;1.0000E-5

DB 73H,0D1H,0B7H ;1.0000E-4

DB 77H,83H,12H ;1.0000E-3

DB 7AH,0A3H,0D7H ;1.0000E-2

DB 7DH,0CCH,0CDH ;1.0000E-1

BFL0: DB 1,80H,00H ;1.0000

DB 4,0A0H,00H ;1.0000E1

DB 7,0C8H,00H ;1.0000E2

DB 0AH,0FAH,00H ;1.0000E3

DB 0EH,9CH,40H ;1.0000E4

DB 11H,0C3H,50H ;1.0000E5

DB 14H,0F4H,24H ;1.0000E6

DB 18H,98H,97H ;1.0000E7

DB 1BH,0BEH,0BCH ;1.0000E8

DB 1EH,0EEH,6BH ;1.0000E9

DB 22H,95H,03H ;1.0000E10

DB 25H,0BAH,44H ;1.0000E11

DB 28H,0E8H,0D5H ;1.0000E12

DB 2CH,91H,85H ;1.0000E13

DB 2FH,0B5H,0E6H ;1.0000E14

DB 32H,0E3H,60H ;1.0000E15

DB 36H,8EH,1CH ;1.0000E16

DB 39H,31H,0A3H ;1.0000E17

DB 3CH,0DEH,0BH ;1.0000E18

DB 40H,8AH,0C7H ;1.0000E19

(28) 標(biāo)號： FCOS 功能：浮點(diǎn)余弦函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中。

影響資源：DPTR、PSW、A、B、R2～R7、位1DH～1FH 堆棧需求： 6字節(jié)

FCOS: LCALL FABS ;COS(-X) = COS X

MOV R5,#1 ;常數(shù)1.5708(π/2)

MOV R6,#0C9H

MOV R7,#10H

CLR 1EH

LCALL MVR0

CLR F0

LCALL AS1 ;x+(π/2)

LCALL MOV0 ;保存結(jié)果，接著運(yùn)行下面的FSIN程序

(29) 標(biāo)號： FSIN 功能：浮點(diǎn)正弦函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中。

影響資源：DPTR、PSW、A、B、R2～R7、位1DH～1FH 堆棧需求： 6字節(jié)

FSIN: MOV A,@R0

MOV C,ACC.7

MOV 1DH,C ;保存自變量的符號

CLR ACC.7 ;統(tǒng)一按正數(shù)計算

MOV @R0,A

LCALL MVR0 ;將[R0]傳送到第一工作區(qū)

MOV R5,#0 ;系數(shù)0.636627(2/π)

MOV R6,#0A2H

MOV R7,#0FAH

CLR 1EH

LCALL MUL1 ;相乘，自變量按(π/2)規(guī)一化

MOV A,R2 ;將結(jié)果復(fù)制到第二區(qū)

MOV R5,A

MOV A,R3

MOV R6,A

MOV A,R4

MOV R7,A

LCALL INT ;第一區(qū)取整，獲得象限信息

MOV A,R2

JZ SIN2

SIN1: CLR C ;將浮點(diǎn)象限數(shù)轉(zhuǎn)換成定點(diǎn)象限數(shù)

LCALL RR1

CJNE R2,#10H,SIN1

MOV A,R4

JNB ACC.1,SIN2

CPL 1DH ;對于第三、四象限，結(jié)果取反

SIN2: JB ACC.0,SIN3

CPL 1FH ;對于第一、三象限，直接求規(guī)一化的小數(shù)

SJMP SIN4

SIN3: MOV A,R4 ;對于第二、四象限，準(zhǔn)備求其補(bǔ)數(shù)

INC A

MOV R4,A

JNZ SIN4

INC R3

SIN4: LCALL RLN ;規(guī)格化

SETB F0

LCALL AS1 ;求自變量歸一化等效值

LCALL MOV0 ;回傳

LCALL FPLN ;用多項(xiàng)式計算正弦值

DB 7DH,93H,28H;0.07185

DB 41H,0,0 ;0

DB 80H,0A4H,64H;-0.64215

DB 41H,0,0 ;0

DB 1,0C9H,2;1.5704

DB 41H,0,0 ;0

DB 40H ;結(jié)束

MOV A,@R0 ;結(jié)果的絕對值超過1.00嗎?

JZ SIN5

JB ACC.6,SIN5

INC R0 ;絕對值按1.00封頂

MOV @R0,#80H[!--empirenews.page--]

INC R0

MOV @R0,#0

DEC R0

DEC R0

MOV A,#1

SIN5: MOV C,1DH ;將數(shù)符拼入結(jié)果中

MOV ACC.7,C

MOV @R0,A

RET

(30) 標(biāo)號： FATN 功能：浮點(diǎn)反正切函數(shù)

入口條件：操作數(shù)在[R0]中。

出口信息：結(jié)果仍在[R0]中。

影響資源：DPTR、PSW、A、B、R2～R7、位1CH～1FH 堆棧需求：7字節(jié)

FATN: MOV A,@R0

MOV C,ACC.7

MOV 1DH,C ;保存自變量數(shù)符

CLR ACC.7 ;自變量取絕對值

MOV @R0,A

CLR 1CH ;清求余運(yùn)算標(biāo)志

JB ACC.6,ATN1;自變量為純小數(shù)否?

JZ ATN1

SETB 1CH ;置位求余運(yùn)算標(biāo)志

LCALL FRCP ;通過倒數(shù)運(yùn)算，轉(zhuǎn)換成純小數(shù)

ATN1: LCALL FPLN ;通過多項(xiàng)式運(yùn)算，計算反正切函數(shù)值

DB 0FCH,0E4H,91H;-0.055802

DB 7FH,8FH,37H;0.27922

DB 0FFH,0EDH,0E0H;-0.46460

DB 7BH,0E8H,77H;0.028377

DB 0,0FFH,68H;0.9977

DB 72H,85H,0ECH;3.1930×10-5

DB 40H ;結(jié)束

JNB 1CH,ATN2;需要求余運(yùn)算否?

CPL 1FH ;準(zhǔn)備運(yùn)算標(biāo)志

MOV C,1FH

MOV F0,C ;常數(shù)1.5708(π/2)

MOV R5,#1

MOV R6,#0C9H

MOV R7,#10H

LCALL AS1 ;求余運(yùn)算

LCALL MOV0 ;回傳

ATN2: MOV A,@R0 ;拼入結(jié)果的數(shù)符

MOV C,1DH

MOV ACC.7,C

MOV @R0,A

RET

(31) 標(biāo)號： RTOD 功能：浮點(diǎn)弧度數(shù)轉(zhuǎn)換成浮點(diǎn)度數(shù)

入口條件：浮點(diǎn)弧度數(shù)在[R0]中。

出口信息：轉(zhuǎn)換成的浮點(diǎn)度數(shù)仍在[R0]中。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

RTOD: MOV R5,#6 ;系數(shù)(180/π)傳送到第二工作區(qū)

MOV R6,#0E5H

MOV R7,#2FH

SJMP DR ;通過乘法進(jìn)行轉(zhuǎn)換

(32) 標(biāo)號： DTOR 功能：浮點(diǎn)度數(shù)轉(zhuǎn)換成浮點(diǎn)弧度數(shù)

入口條件：浮點(diǎn)度數(shù)在[R0]中。

出口信息：轉(zhuǎn)換成的浮點(diǎn)弧度數(shù)仍在[R0]中。

影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：6字節(jié)

DTOR: MOV R5,#0FBH;系數(shù)(π/180)傳送到第二工作區(qū)

MOV R6,#8EH

MOV R7,#0FAH

DR: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)

CLR 1EH ;系數(shù)為正

LCALL MUL1 ;通過乘法進(jìn)行轉(zhuǎn)換

LJMP MOV0 ;結(jié)果傳送到[R0]中

END

擴(kuò)展閱讀：關(guān)于匯編和C的比較